File Coverage

blib/lib/Tags/HTML/Page/Begin.pm

Criterion	Covered	Total	%
statement	134	134	100.0
branch	54	54	100.0
condition	3	3	100.0
subroutine	13	13	100.0
pod	1	1	100.0
total	205	205	100.0

package Tags::HTML::Page::Begin;

use base qw(Tags::HTML);
use strict;
use warnings;

use Class::Utils qw(set_params split_params);
use Error::Pure qw(err);
use List::Util 1.33 qw(none);
use Readonly;

# Constants.
Readonly::Hash my %LANG => (
	'title' => 'Page title',
);

our $VERSION = 0.17;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my ($object_params_ar, $other_params_ar) = split_params(
		['application-name', 'author', 'base_href', 'base_target',
		'css_init', 'css_src', 'charset', 'description', 'doctype',
		'favicon', 'generator', 'html_lang', 'http_equiv_content_type',
		'keywords', 'lang', 'refresh', 'robots', 'rss',
		'script_js', 'script_js_src', 'viewport'], @params);
	my $self = $class->SUPER::new(@{$other_params_ar});

	# Application name.
	$self->{'application-name'} = undef;

	# Author.
	$self->{'author'} = undef;

	# Base element.
	$self->{'base_href'} = undef;
	$self->{'base_target'} = undef;

	# Init CSS style.
	$self->{'css_init'} = [
		['s', '*'],
		['d', 'box-sizing', 'border-box'],
		['d', 'margin', 0],
		['d', 'padding', 0],
		['e'],
	];

	# CSS links.
	$self->{'css_src'} = [];

	# Charset.
	$self->{'charset'} = 'UTF-8';

	# Description.
	$self->{'description'} = undef;

	# Doctype.
	$self->{'doctype'} = '';

	# Favicon.
	$self->{'favicon'} = undef;

	# Generator.
	$self->{'generator'} = 'Perl module: '.__PACKAGE__.', Version: '.$VERSION;

	# HTML element lang attribute.
	$self->{'html_lang'} = 'en';

	# http-equiv content-type.
	$self->{'http_equiv_content_type'} = 'text/html';

	# Keywords.
	$self->{'keywords'} = undef;

	# Languages.
	$self->{'lang'} = \%LANG;

	# Refresh.
	$self->{'refresh'} = undef;

	# Robots.
	$self->{'robots'} = undef;

	# RSS
	$self->{'rss'} = undef;

	# Script js code.
	$self->{'script_js'} = [];

	# Script js sources.
	$self->{'script_js_src'} = [];

	# Viewport.
	$self->{'viewport'} = 'width=device-width, initial-scale=1.0';

	# Process params.
	set_params($self, @{$object_params_ar});

	# Check for 'css_src' array.
	if (ref $self->{'css_src'} ne 'ARRAY') {
		err "Parameter 'css_src' must be a array.";
	}
	foreach my $css_src_hr (@{$self->{'css_src'}}) {
		if (ref $css_src_hr ne 'HASH') {
			err "Parameter 'css_src' must be a array of hash structures.";
		}
		foreach my $key (keys %{$css_src_hr}) {
			if (none { $key eq $_ } qw(link media)) {
				err "Parameter 'css_src' must be a array of hash ".
					"structures with 'media' and 'link' keys."
			}
		}
	}

	# Check charset.
	if (! defined $self->{'charset'}) {
		err "Parameter 'charset' is required.";
	}

	# Check for 'script_js' array.
	if (ref $self->{'script_js'} ne 'ARRAY') {
		err "Parameter 'script_js' must be a array.";
	}

	# Check for 'script_js_src' array.
	if (ref $self->{'script_js_src'} ne 'ARRAY') {
		err "Parameter 'script_js_src' must be a array.";
	}

	# Check for favicon.
	if (defined $self->{'favicon'} && $self->{'favicon'} !~ m/\.(ico|png|jpg|gif|svg)$/ms) {
		err "Parameter 'favicon' contain bad image type.";
	}

	# Object.
	return $self;
}

# Process 'Tags'.
sub _process {
	my $self = shift;

	my $css;
	if ($self->{'css'}) {
		$css = $self->{'css'}->flush(1);
		if ($css ne '') {
			$css .= "\n";
		} else {
			undef $css;
		}
	}

	# Begin of page.
	$self->{'tags'}->put(
		['r', $self->{'doctype'}],
		['r', "\n"],
		['b', 'html'],
		['a', 'lang', $self->{'html_lang'}],
		['b', 'head'],
	);

	if (defined $self->{'http_equiv_content_type'}) {
		$self->{'tags'}->put(
			['b', 'meta'],
			['a', 'http-equiv', 'Content-Type'],
			['a', 'content', $self->{'http_equiv_content_type'}.
				'; charset='.$self->{'charset'}],
			['e', 'meta'],
		);
	}
	if (defined $self->{'base_href'}) {
		$self->{'tags'}->put(
			['b', 'base'],
			['a', 'href', $self->{'base_href'}],
			defined $self->{'base_target'} ? (
				['a', 'target', $self->{'base_target'}],
			) : (),
			['e', 'base'],
		);
	}
	if (! defined $self->{'http_equiv_content_type'}) {
		$self->{'tags'}->put(
			['b', 'meta'],
			['a', 'charset', $self->{'charset'}],
			['e', 'meta'],
		);
	}
	$self->_meta('application-name');
	$self->_meta('author');
	$self->_meta('description');
	$self->_meta('generator');
	$self->_meta('keywords');
	$self->_meta('robots');
	$self->_meta('viewport');
	if (defined $self->{'refresh'}) {
		$self->{'tags'}->put(
			['b', 'meta'],
			['a', 'http-equiv', 'refresh'],
			['a', 'content', $self->{'refresh'}],
			['e', 'meta'],
		);
	}

	$self->_favicon;

	if (@{$self->{'script_js'}}) {
		foreach my $script_js (@{$self->{'script_js'}}) {
			$self->{'tags'}->put(
				['b', 'script'],
				['a', 'type', 'text/javascript'],
				['d', $script_js],
				['e', 'script'],
			);
		}
	}
	if (@{$self->{'script_js_src'}}) {
		foreach my $script_js_src (@{$self->{'script_js_src'}}) {
			$self->{'tags'}->put(
				['b', 'script'],
				['a', 'type', 'text/javascript'],
				['a', 'src', $script_js_src],
				['e', 'script'],
			);
		}
	}

	$self->{'tags'}->put(
		defined $self->{'lang'}->{'title'} ? (
			['b', 'title'],
			['d', $self->{'lang'}->{'title'}],
			['e', 'title'],
		) : (),

		(
			defined $css ? (
				['b', 'style'],
				['a', 'type', 'text/css'],
				['d', $css],
				['e', 'style'],
			) : (),
		),
	);
	if (@{$self->{'css_src'}}) {
		foreach my $css_src_hr (@{$self->{'css_src'}}) {
			$self->{'tags'}->put(
				['b', 'link'],
				['a', 'rel', 'stylesheet'],
				['a', 'href', $css_src_hr->{'link'}],
				$css_src_hr->{'media'} ? (
					['a', 'media', $css_src_hr->{'media'}],
				) : (),
				['a', 'type', 'text/css'],
				['e', 'link'],
			);
		}
	}

	if (defined $self->{'rss'}) {
		$self->{'tags'}->put(
			['b', 'link'],
			['a', 'rel', 'alternate'],
			['a', 'type', 'application/rss+xml'],
			['a', 'title', 'RSS'],
			['a', 'href', $self->{'rss'}],
			['e', 'link'],
		);
	}

	$self->{'tags'}->put(
		['e', 'head'],
		['b', 'body'],
	);

	return;
}

sub _process_css {
	my $self = shift;

	$self->{'css'}->put(
		@{$self->{'css_init'}},
	);

	return;
}

sub _favicon {
	my $self = shift;

	if (! defined $self->{'favicon'}) {
		return;
	}

	my ($suffix) = $self->{'favicon'} =~ m/\.(ico|png|jpg|gif|svg)$/ms;
	my $image_type;
	if ($suffix eq 'ico') {
		$image_type = 'image/vnd.microsoft.icon';
	} elsif ($suffix eq 'png') {
		$image_type = 'image/png';
	} elsif ($suffix eq 'svg') {
		$image_type = 'image/svg+xml';
	} elsif ($suffix eq 'gif') {
		$image_type = 'image/gif';
	} else {
		$image_type = 'image/jpeg';
	}

	$self->{'tags'}->put(
		['b', 'link'],
		['a', 'rel', 'icon'],
		['a', 'href', $self->{'favicon'}],
		['a', 'type', $image_type],
		['e', 'link'],
	);

	return;
}

sub _meta {
	my ($self, $key) = @_;

	if (! defined $self->{$key}) {
		return;
	}

	$self->{'tags'}->put(
		['b', 'meta'],
		['a', 'name', $key],
		['a', 'content', $self->{$key}],
		['e', 'meta'],
	);

	return;
}

1;

__END__