File Coverage

blib/lib/Tags/HTML/Container.pm

Criterion	Covered	Total	%
statement	76	76	100.0
branch	16	16	100.0
condition			n/a
subroutine	17	17	100.0
pod	1	1	100.0
total	110	110	100.0

package Tags::HTML::Container;

use base qw(Tags::HTML);
use strict;
use warnings;

use Class::Utils qw(set_params split_params);
use Error::Pure qw(err);
use List::Util 1.33 qw(none);
use Mo::utils 0.01 qw(check_required);
use Mo::utils::CSS 0.07 qw(check_css_class check_css_unit);
use Readonly;

Readonly::Array our @HORIZ_ALIGN => qw(center left right);
Readonly::Array our @VERT_ALIGN => qw(base bottom center fit top);
Readonly::Hash our %VERT_CONV => (
	'base' => 'baseline',
	'bottom' => 'flex-end',
	'center' => 'center',
	'fit' => 'stretch',
	'top' => 'flex-start',
);

our $VERSION = 0.10;

sub new {
	my ($class, @params) = @_;

	# Create object.
	my ($object_params_ar, $other_params_ar) = split_params(
		['css_container', 'css_inner', 'height', 'horiz_align',
		'padding', 'vert_align'], @params);
	my $self = $class->SUPER::new(@{$other_params_ar});

	# Container align.
	$self->{'horiz_align'} = 'center';
	$self->{'vert_align'} = 'center';

	# CSS classes.
	$self->{'css_container'} = 'container';
	$self->{'css_inner'} = 'inner';

	# Height.
	$self->{'height'} = '100vh';

	# Padding.
	$self->{'padding'} = undef;

	# Process params.
	set_params($self, @{$object_params_ar});

	check_required($self, 'horiz_align');
	if (none { $self->{'horiz_align'} eq $_ } @HORIZ_ALIGN) {
		err "Parameter 'horiz_align' have a bad value.",
			'Value', $self->{'horiz_align'},
		;
	}

	check_required($self, 'vert_align');
	if (none { $self->{'vert_align'} eq $_ } @VERT_ALIGN) {
		err "Parameter 'vert_align' have a bad value.",
			'Value', $self->{'vert_align'},
		;
	}

	check_css_class($self, 'css_container');
	check_css_class($self, 'css_inner');

	check_css_unit($self, 'height');
	check_css_unit($self, 'padding');

	# Object.
	return $self;
}

sub _cleanup {
	my ($self, $cleanup_cb) = @_;

	if (defined $cleanup_cb) {
		$cleanup_cb->($self);
	}

	return;
}

sub _init {
	my ($self, $init_cb) = @_;

	if (defined $init_cb) {
		$init_cb->($self);
	}

	return;
}

sub _prepare {
	my ($self, $prepare_cb) = @_;

	if (defined $prepare_cb) {
		$prepare_cb->($self);
	}

	return;
}

sub _process {
	my ($self, $tags_cb) = @_;

	if (! defined $tags_cb) {
		err "There is no contained callback with Tags code.";
	}

	$self->{'tags'}->put(
		['b', 'div'],
		['a', 'class', $self->{'css_container'}],
		['b', 'div'],
		['a', 'class', $self->{'css_inner'}],
	);
	$tags_cb->($self);
	$self->{'tags'}->put(
		['e', 'div'],
		['e', 'div'],
	);

	return;
}

sub _process_css {
	my ($self, $css_cb) = @_;

	$self->{'css'}->put(
		['s', '.'.$self->{'css_container'}],
		['d', 'display', 'flex'],
		['d', 'align-items', $VERT_CONV{$self->{'vert_align'}}],
		['d', 'justify-content', $self->{'horiz_align'}],
		['d', 'height', $self->{'height'}],
		defined $self->{'padding'} ? (
			['d', 'padding', $self->{'padding'}],
		) : (),
		['e'],
	);
	if (defined $css_cb) {
		$css_cb->($self);
	}

	return;
}

1;

__END__