File Coverage

blib/lib/Tags/HTML/CPAN/Changes.pm

Criterion	Covered	Total	%
statement	84	84	100.0
branch	18	18	100.0
condition	9	9	100.0
subroutine	15	15	100.0
pod	1	1	100.0
total	127	127	100.0

package Tags::HTML::CPAN::Changes;

use base qw(Tags::HTML);
use strict;
use warnings;

use Class::Utils qw(set_params split_params);
use CPAN::Version;
use English;
use Error::Pure qw(err);
use Mo::utils 0.01 qw(check_required);
use Mo::utils::CSS 0.02 qw(check_css_class);
use Scalar::Util qw(blessed);

our $VERSION = 0.06;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my ($object_params_ar, $other_params_ar) = split_params(
		['css_class'], @params);
	my $self = $class->SUPER::new(@{$other_params_ar});

	# CSS class.
	$self->{'css_class'} = 'changes';

	# Process params.
	set_params($self, @{$object_params_ar});

	check_required($self, 'css_class');
	check_css_class($self, 'css_class');

	# Object.
	return $self;
}

sub _cleanup {
	my $self = shift;

	delete $self->{'_changes'};

	return;
}

sub _init {
	my ($self, $changes) = @_;

	if (! defined $changes
		|| ! blessed($changes)
		|| ! $changes->isa('CPAN::Changes')) {

		err "Data object must be a 'CPAN::Changes' instance.";
	}

	if (CPAN::Version->vlt($changes->VERSION, '0.500002')) {
		err "Minimal version of supported CPAN::Changes is 0.500002.",
			'Version', $changes->VERSION,
		;
	}

	$self->{'_changes'} = $changes;

	return;
}

# Process 'Tags'.
sub _process {
	my $self = shift;

	if (! exists $self->{'_changes'}) {
		return;
	}

	$self->{'tags'}->put(
		['b', 'div'],
		['a', 'class', $self->{'css_class'}],
	);
	if ($self->{'_changes'}->preamble ne '') {
		$self->{'tags'}->put(
			['b', 'h1'],
			['d', $self->{'_changes'}->preamble],
			['e', 'h1'],
		);
	}
	foreach my $changes_rel (sort { $b->version <=> $a->version } $self->{'_changes'}->releases) {
		my $version = $changes_rel->version;
		if (defined $changes_rel->date) {
			$version .= ' - '.$changes_rel->date;
		}
		if (defined $changes_rel->note) {
			$version .= ' '.$changes_rel->note;
		}
		$self->{'tags'}->put(
			['b', 'div'],
			['a', 'class', 'version'],
			['b', 'h2'],
			['d', $version],
			['e', 'h2'],
		);
		$self->{'tags'}->put(
			['b', 'ul'],
			['a', 'class', 'version-changes'],
		);
		foreach my $entry (@{$changes_rel->entries}) {
			if (defined $entry->text && $entry->text ne '') {
				if (@{$entry->entries}) {
					$self->{'tags'}->put(
						['b', 'h3'],
						['d', '['.$entry->text.']'],
						['e', 'h3'],
					);
				} else {
					$self->{'tags'}->put(
						['b', 'li'],
						['a', 'class', 'version-change'],
						['d', $entry->text],
						['e', 'li'],
					);
				}
			}
			foreach my $change (@{$entry->entries}) {
				$self->{'tags'}->put(
					['b', 'li'],
					['a', 'class', 'version-change'],
					['d', $change->text],
					['e', 'li'],
				);
			}
		}
		$self->{'tags'}->put(
			['e', 'ul'],
		);
		$self->{'tags'}->put(
			['e', 'div'],
		);
	}
	$self->{'tags'}->put(
		['e', 'div'],
	);

	return;
}

sub _process_css {
	my $self = shift;

	if (! exists $self->{'_changes'}) {
		return;
	}

	$self->{'css'}->put(
		['s', '.'.$self->{'css_class'}],
		['d', 'max-width', '800px'],
		['d', 'margin', 'auto'],
		['d', 'background', '#fff'],
		['d', 'padding', '20px'],
		['d', 'border-radius', '8px'],
		['d', 'box-shadow', '0 2px 4px rgba(0, 0, 0, 0.1)'],
		['d', 'font-family', 'Arial, Helvetica, sans-serif'],
		['e'],

		['s', '.'.$self->{'css_class'}.' .version'],
		['d', 'border-bottom', '2px solid #eee'],
		['d', 'padding-bottom', '20px'],
		['d', 'margin-bottom', '20px'],
		['e'],

		['s', '.'.$self->{'css_class'}.' .version:last-child'],
		['d', 'border-bottom', 'none'],
		['e'],

		['s', '.'.$self->{'css_class'}.' .version h2'],
		['s', '.'.$self->{'css_class'}.' .version h3'],
		['d', 'color', '#007BFF'],
		['d', 'margin-top', 0],
		['e'],

		['s', '.'.$self->{'css_class'}.' .version-changes'],
		['d', 'list-style-type', 'none'],
		['d', 'padding-left', 0],
		['e'],

		['s', '.'.$self->{'css_class'}.' .version-change'],
		['d', 'background-color', '#f8f9fa'],
		['d', 'margin', '10px 0'],
		['d', 'padding', '10px'],
		['d', 'border-left', '4px solid #007BFF'],
		['d', 'border-radius', '4px'],
		['e'],
	);

	return;
}

1;

__END__