File Coverage

blib/lib/Tags/Utils/Preserve.pm

Criterion	Covered	Total	%
statement	52	52	100.0
branch	11	12	91.6
condition	6	6	100.0
subroutine	12	12	100.0
pod	6	6	100.0
total	87	88	98.8

package Tags::Utils::Preserve;

use strict;
use warnings;

use Class::Utils qw(set_params);
use List::Util 1.33 qw(any);
use Readonly;

# Constants.
Readonly::Scalar my $LAST_INDEX => -1;

our $VERSION = 0.16;

# Constructor.
sub new {
	my ($class, @params) = @_;
	my $self = bless {}, $class;

	# Preserved elements.
	$self->{'preserved'} = [];

	# Process params.
	set_params($self, @params);

	# Initialization.
	$self->reset;

	# Object.
	return $self;
}

# Process for begin of element.
sub begin {
	my ($self, $element) = @_;

	$self->save_previous;
	if (scalar @{$self->{'preserved'}}
		&& any { $element eq $_ } @{$self->{'preserved'}}) {

		push @{$self->{'preserved_stack'}}, $element;
		$self->{'preserved_flag'} = 1;
	}

	# Return preserved flags.
	return wantarray
		? ($self->{'preserved_flag'}, $self->{'prev_preserved_flag'})
		: $self->{'preserved_flag'};
}

# Process for end of element.
sub end {
	my ($self, $element) = @_;

	$self->save_previous;
	my $stack = $self->{'preserved_stack'};
	if (scalar @{$stack} && $element eq $stack->[$LAST_INDEX]) {
		pop @{$stack};
		if (! scalar @{$stack}) {
			$self->{'preserved_flag'} = 0;
		}
	}

	# Return preserved flags.
	return wantarray
		? ($self->{'preserved_flag'}, $self->{'prev_preserved_flag'})
		: $self->{'preserved_flag'};
}

# Get preserved flag.
sub get {
	my $self = shift;

	# Return preserved flags.
	return wantarray
		? ($self->{'preserved_flag'}, $self->{'prev_preserved_flag'})
		: $self->{'preserved_flag'};
}

# Resets.
sub reset {
	my $self = shift;

	# Preserved flag.
	$self->{'preserved_flag'} = 0;

	# Previsous preserved flag.
	$self->{'prev_preserved_flag'} = 0;

	# Preserved elements.
	$self->{'preserved_stack'} = [];

	return;
}

# Save previous stay.
sub save_previous {
	my $self = shift;

	$self->{'prev_preserved_flag'} = $self->{'preserved_flag'};

	return;
}

1;

__END__