File Coverage

blib/lib/TableDataRole/Source/AOH.pm

Criterion	Covered	Total	%
statement	56	65	86.1
branch	9	18	50.0
condition			n/a
subroutine	11	13	84.6
pod	0	9	0.0
total	76	105	72.3

package TableDataRole::Source::AOH;

use 5.010001;
use strict;
use warnings;

use Role::Tiny;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2024-05-14'; # DATE
our $DIST = 'TableDataRoles-Standard'; # DIST
our $VERSION = '0.025'; # VERSION

with 'TableDataRole::Spec::Basic';

sub new {
    my ($class, %args) = @_;

    my $aoh = delete $args{aoh} or die "Please specify 'aoh' argument";
    my $column_names = delete $args{column_names};
    die "Unknown argument(s): ". join(", ", sort keys %args)
        if keys %args;

    my $self = {
        aoh => $aoh,
        pos => 0,
        # buffer => undef,
        column_names => $column_names,
        # column_idxs  => undef,
    };

    if ($self->{column_names}) {
        $self->{column_idxs} = { map { ($self->{column_names}[$_] => $_) }
                                 0 .. $#{ $self->{column_names} }
                             };
    } else {
        $self->{column_names} = [];
        $self->{column_idxs} = {};
        if (@$aoh) {
            my $row = $aoh->[0];
            my $i = -1;
            for (sort keys %$row) {
                push @{ $self->{column_names} }, $_;
                $self->{column_idxs}{$_} = ++$i;
            }
        }
    }

    bless $self, $class;
}

sub get_column_count {
    my $self = shift;
    my $aoh = $self->{aoh};
    unless (@$aoh) {
        return 0;
    }
    scalar keys(%{ $aoh->[0] });
}

sub get_column_names {
    my $self = shift;
    wantarray ? @{ $self->{column_names} } : $self->{column_names};
}

sub has_next_item {
    my $self = shift;
    $self->{pos} < @{$self->{aoh}};
}

sub get_next_item {
    my $self = shift;
    my $aoh = $self->{aoh};
    die "StopIteration" unless $self->{pos} < @{$aoh};
    my $row_hashref = $aoh->[ $self->{pos}++ ];
    my $row_aryref = [];
    for (keys %$row_hashref) {
        my $idx = $self->{column_idxs}{$_};
        next unless defined $idx;
        $row_aryref->[$idx] = $row_hashref->{$_};
    }
    $row_aryref;
}

sub get_next_row_hashref {
    my $self = shift;
    my $aoh = $self->{aoh};
    die "StopIteration" unless $self->{pos} < @{$aoh};
    $aoh->[ $self->{pos}++ ];
}

sub get_row_count {
    my $self = shift;
    scalar(@{ $self->{aoh} });
}

sub reset_iterator {
    my $self = shift;
    $self->{pos} = 0;
}

sub get_iterator_pos {
    my $self = shift;
    $self->{pos};
}

1;
# ABSTRACT: Get table data from an array of hashes

__END__