File Coverage

blib/lib/TableDataRole/Munge/MungeColumns.pm

Criterion	Covered	Total	%
statement	14	78	17.9
branch	0	28	0.0
condition	0	5	0.0
subroutine	5	14	35.7
pod	1	8	12.5
total	20	133	15.0

package TableDataRole::Munge::MungeColumns;

use 5.010001;
use strict;
use warnings;
use Log::ger;

use Role::Tiny;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2024-05-14'; # DATE
our $DIST = 'TableDataRoles-Standard'; # DIST
our $VERSION = '0.025'; # VERSION

with 'TableDataRole::Spec::Basic';

sub new {
    require Module::Load::Util;

    my ($class, %args) = @_;

    my $tabledata = delete $args{tabledata}
        or die "Please supply 'tabledata' argument";
    my $munge_column_names = delete $args{munge_column_names}
        or die "Please supply 'munge_column_names' argument";
    my $munge = delete $args{munge};
    my $munge_hashref = delete $args{munge_hashref};
    ($munge || $munge_hashref)
        or die "Please supply 'munge' or 'munge_hashref' argument";
    for ($munge_column_names, $munge, $munge_hashref) {
        next unless defined;
        unless (ref $_ eq 'CODE') {
            my $code = "package main; sub { no strict; no warnings; $_ }";
            log_trace "Eval-ing: $code";
            $_ = eval $code; ## no critic: BuiltinFunctions::ProhibitStringyEval
            die if $@;
        }
    }
    my $load = delete($args{load}) // 1;
    die "Unknown argument(s): ". join(", ", sort keys %args)
        if keys %args;

    $tabledata = Module::Load::Util::instantiate_class_with_optional_args({load=>$load, ns_prefix=>"TableData"}, $tabledata);
    my $column_names = $munge_column_names->(scalar $tabledata->get_column_names);

    bless {
        tabledata => $tabledata,
        column_names => $column_names,
        column_idxs => {map {$column_names->[$_] => $_} 0..$#{$column_names}},
        munge_column_names => $munge_column_names,
        munge => $munge,
        munge_hashref => $munge_hashref,
        pos => 0, # iterator
        # buffer => undef,
    }, $class;
}

sub get_column_count {
    my $self = shift;

    scalar @{ $self->{column_names} };
}

sub get_column_names {
    my $self = shift;
    wantarray ? @{ $self->{column_names} } : $self->{column_names};
}

sub _fill_buffer {
    my $self = shift;
    return if $self->{buffer};
    while (1) {
        return unless $self->{tabledata}->has_next_item;
        if ($self->{munge}) {
            my $row = $self->{tabledata}->get_next_row_arrayref;
            my $munged_row = $self->{munge}->($row);
            $self->{buffer} = $munged_row;
            return;
        } else {
            my $row = $self->{tabledata}->get_next_item;
            my $row_hashref = { map {$self->{column_names}[$_] => $row->[$_]} 0..$#{$row} };
            my $munged_row_hashref = $self->{munge_hashref}->($row_hashref);
            my $munged_row = [];
            $munged_row->[ $self->{column_idxs}{$_} ] = $munged_row_hashref->{$_} for keys %$munged_row_hashref;
            $self->{buffer} = $munged_row;
            return;
        }
    }
}

sub has_next_item {
    my $self = shift;
    return 1 if $self->{buffer};
    $self->_fill_buffer;
    return $self->{buffer} ? 1:0;
}

sub get_next_item {
    my $self = shift;
    $self->_fill_buffer;
    die "StopIteration" unless $self->{buffer};
    $self->{pos}++;
    return delete $self->{buffer};
}

sub get_next_row_hashref {
    my $self = shift;
    my $row = $self->get_next_item;
    +{ map {($self->{column_names}->[$_] => $row->[$_])} 0..$#{$row} };
}

sub get_iterator_pos {
    my $self = shift;
    $self->{pos};
}

sub reset_iterator {
    my $self = shift;
    $self->{tabledata}->reset_iterator;
    $self->{pos} = 0;
}

1;
# ABSTRACT: Role to munge (add, remove, rename, reorder) columns of each row from another tabledata

__END__