File Coverage

blib/lib/TableDataRole/Munge/GroupRows.pm

Criterion	Covered	Total	%
statement	38	38	100.0
branch	8	14	57.1
condition	3	6	50.0
subroutine	7	7	100.0
pod	1	1	100.0
total	57	66	86.3

package TableDataRole::Munge::GroupRows;

use 5.010001;
use strict;
use warnings;
use Log::ger;

use Role::Tiny;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2024-05-14'; # DATE
our $DIST = 'TableDataRoles-Standard'; # DIST
our $VERSION = '0.025'; # VERSION

with 'TableDataRole::Spec::Basic';
with 'TableDataRole::Source::AOA';

sub new {
    require Module::Load::Util;

    my ($class, %args) = @_;

    my $tabledata = delete $args{tabledata}
        or die "Please supply 'tabledata' argument";
    my $key = delete($args{key}) // 'key';
    length($key) > 1 or die "Argument 'key' cannot be empty";
    $key ne 'rows' or die "Argument 'key' cannot have the value of 'rows'";
    my $calc_key = delete $args{calc_key}
        or die "Please supply 'calc_key' argument";
    my $load = delete($args{load}) // 1;
    die "Unknown argument(s): ". join(", ", sort keys %args)
        if keys %args;

    my $td = Module::Load::Util::instantiate_class_with_optional_args(
        {load=>$load, ns_prefix=>"TableData"}, $tabledata);

    # group the rows now into aoa
    my $aoa = [];
    {
        my %rownum; # key=calculated key, val=rownum
        $td->each_row_arrayref(
            sub {
                my $row_arrayref = shift;
                my $row_hashref = $td->convert_row_arrayref_to_hashref($row_arrayref);
                my $key = $calc_key->($row_hashref, $aoa);
                defined $key or die "BUG: calc_key produced undef key!";
                unless (defined $rownum{$key}) {
                    $rownum{$key} = @$aoa;
                    $aoa->[ $rownum{$key} ] //= [$key, []];
                }
                push @{ $aoa->[ $rownum{$key} ][1] }, $row_arrayref;
            });
    }

    bless {
        tabledata => $tabledata,
        _tabledata => $td,
        column_names => [$key, 'rows'],
        column_idxs => {$key=>0, rows=>1},
        aoa => $aoa,
        pos => 0,
    }, $class;
}

1;
# ABSTRACT: Role to group rows from another tabledata

__END__