File Coverage

blib/lib/TableDataRole/Spec/Basic.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	1	2	50.0
condition			n/a
subroutine	10	10	100.0
pod	9	9	100.0
total	61	62	98.3

## no critic: TestingAndDebugging::RequireUseStrict
package TableDataRole::Spec::Basic;

use Role::Tiny;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2023-11-25'; # DATE
our $DIST = 'TableData'; # DIST
our $VERSION = '0.2.6'; # VERSION

### constructor

requires 'new';

### mixins

with 'Role::TinyCommons::Iterator::Resettable';

### additional method names to return hashref

requires 'get_next_row_hashref';

### column information

requires 'get_column_count';
requires 'get_column_names';

### aliases, for convenience and clarity

sub has_next_row {
    my $self = shift;
    $self->has_next_item(@_);
}

sub get_next_row_arrayref {
    my $self = shift;
    $self->get_next_item(@_);
}

sub get_row_count {
    my $self = shift;
    $self->get_item_count(@_);
}

sub get_all_rows_arrayref {
    my $self = shift;
    $self->get_all_items(@_);
}

sub get_all_rows_hashref {
    my $self = shift;

    my @items;
    $self->reset_iterator;
    while ($self->has_next_item) {
        my $row = $self->get_next_row_hashref;
        push @items, $row;
    }
    @items;
}

sub each_row_arrayref {
    my $self = shift;
    $self->each_item(@_);
}

sub each_row_hashref {
    my ($self, $coderef) = @_;

    $self->reset_iterator;
    my $index = 0;
    while ($self->has_next_item) {
        my $row = $self->get_next_row_hashref;
        my $res = $coderef->($row, $self, $index);
        return 0 unless $res;
        $index++;
    }
    return 1;
}

sub convert_row_arrayref_to_hashref {
    my ($self, $row_arrayref) = @_;

    my $row_hashref = {};
    my @column_names = $self->get_column_names;
    for my $i (0 .. $#column_names) {
        $row_hashref->{ $column_names[$i] } = $row_arrayref->[$i];
    }
    $row_hashref;
}

sub convert_row_hashref_to_arrayref {
    my ($self, $row_hashref) = @_;

    my $row_arrayref = [];
    my @column_names = $self->get_column_names;
    for my $i (0 .. $#column_names) {
        $row_arrayref->[$i] = $row_hashref->{ $column_names[$i] };
    }
    $row_arrayref;
}

1;
# ABSTRACT: Basic interface for all TableData::* modules

__END__