File Coverage

blib/lib/Sys/Signals/Block.pm

Criterion	Covered	Total	%
statement	52	53	98.1
branch	13	20	65.0
condition			n/a
subroutine	11	11	100.0
pod	3	3	100.0
total	79	87	90.8

package Sys::Signals::Block;

use 5.008;
use strict;
use base qw(Class::Accessor::Fast);

use Carp qw(croak);
use POSIX qw(sigprocmask SIG_BLOCK SIG_UNBLOCK);

our $VERSION = '0.10';

__PACKAGE__->mk_accessors(qw(sigset is_blocked));

# mapping of signame => number
my %SigNum = _get_signums();

sub import {
    my $class = shift;

    if (@_) {
        my @sigs = $class->_parse_signals(@_)
            or croak "no signals listed on import line";

        my $sigset = POSIX::SigSet->new(@sigs)
            or croak "Can't create SigSet: $!";

        $class->instance->sigset($sigset);
    }
}

# convert signal names to numbers
sub _get_signums {
    require Config;

    my @names = split /\s+/, $Config::Config{sig_name};
    my @nums  = split /[\s,]+/, $Config::Config{sig_num};

    my %sigs;
    @sigs{@names} = @nums;

    return %sigs;
}

sub _parse_signals {
    my ($class, @signals) = @_;

    my @nums;

    for my $signal (@signals) {
        unless ($signal =~ /\D/) {
            push @nums, $signal;
        }
        else {
            $signal =~ s/^SIG//;
            my $num = $SigNum{$signal};
            unless (defined $num) {
                croak "invalid signal name: 'SIG${signal}'";
            }

            push @nums, $num;
        }
    }

    return @nums;
}

my $Instance;

sub instance {
    my $class = shift;

    unless ( defined $Instance ) {
        $Instance = $class->new({ is_blocked => 0 });
    }

    return $Instance;
}

sub block {
    my $self = shift->instance;

    return if $self->is_blocked;

    my $retval = sigprocmask(SIG_BLOCK, $self->sigset);

    if ($retval) {
        $self->is_blocked(1);
    }

    return $retval;
}

sub unblock {
    my $self = shift->instance;

    return unless $self->is_blocked;

    my $retval = sigprocmask(SIG_UNBLOCK, $self->sigset);

    if ($retval) {
        $self->is_blocked(0);
    }

    return $retval;
}

1;

__END__