File Coverage

blib/lib/Sys/GetRandom/PP.pm

Criterion	Covered	Total	%
statement	44	47	93.6
branch	8	16	50.0
condition	2	6	33.3
subroutine	9	9	100.0
pod	2	2	100.0
total	65	80	81.2

package Sys::GetRandom::PP;
use strict;
use warnings;

use Exporter qw(import);
use Carp qw(croak);
use Sys::GetRandom::PP::_Bits ();
BEGIN {
    my $pkg = do { no strict 'refs'; \%{ __PACKAGE__ . '::' } };
    my $bits = \%Sys::GetRandom::PP::_Bits::;
    for my $sym (qw(GRND_RANDOM GRND_NONBLOCK _SYS_getrandom)) {
        $pkg->{$sym} = $bits->{$sym};
    }
}

our $VERSION = '0.05';

our @EXPORT_OK = qw(
    GRND_RANDOM
    GRND_NONBLOCK
    getrandom
    random_bytes
);

sub getrandom ($$;$) {
    if (@_ < 2 || @_ > 3) {
        croak 'Usage: ' . __PACKAGE__ . '::getrandom($buffer, $length, $flags = 0)';
    }
    my $bufref = \$_[0];
    my (undef, $length, $flags) = @_;
    $length |= 0;
    $flags |= 0;
    $$bufref .= '';
    utf8::downgrade $$bufref;
    my $dlen = $length - length $$bufref;
    $$bufref .= $dlen > 0 ? "\0" x $dlen : '';
    my $r = syscall _SYS_getrandom, $$bufref, $length, $flags;
    if ($r == -1) {
        substr($$bufref, -$dlen) = '' if $dlen > 0;
        return undef;
    }
    substr($$bufref, $r) = '';
    $r
}

sub random_bytes {
    my ($n) = @_;
    $n |= 0;
    $n >= 0 && $n <= 256
        or croak "Argument to random_bytes() must be an integer between 0 and 256, not $n";
    return '' if $n == 0;
    defined(my $r = getrandom(my $buf, $n))
        or die "Internal error: getrandom(\$buf, $n) failed: $!";
    $r == $n
        or die "Internal error: getrandom(\$buf, $n) returned $r";
    $buf
}

1
__END__