File Coverage

blib/lib/Sys/Export/LazyFileData.pm

Criterion	Covered	Total	%
statement	40	44	90.9
branch	6	10	60.0
condition	9	21	42.8
subroutine	12	14	85.7
pod	7	7	100.0
total	74	96	77.0

package Sys::Export::LazyFileData;

our $VERSION = '0.005'; # VERSION
# ABSTRACT: Reference a path and optional range of bytes and load it on demand

use v5.26;
use warnings;
use experimental qw( signatures );
use Carp;
use overload q{""} => \&as_string, q{${}} => \&as_scalarref;
use Cwd ();
use Sys::Export ();


sub new($class, $src, $offset=0, $size=undef) {
   my ($abs, $actual_size);
   if (ref $src eq 'SCALAR') {
      # Ensure is only bytes
      croak "Wide character in file data scalar ref"
         if utf8::is_utf8($src) && !utf8::downgrade($src, 1);
      # If given a scalar-ref, and size and offset are the defaults, then we can just cache that directly.
      return bless [ $src, $src, 0, length $$src ], $class
         if !$offset && (!$size || $size == length $$src);
      $actual_size= length $$src;
   } else {
      $abs= Cwd::abs_path($src) // croak "Can't resolve '$src' to a real file";
      $actual_size= -s $abs;
   }
   $size //= $actual_size - $offset;
   croak "Requested size ($src, $offset+$size) exceeds actual size ($actual_size)"
      if $offset+$size > $actual_size;
   return bless [ undef, $src, $offset, $size, $abs ], $class;
}


sub source   { $_[0][1] }
sub offset   { $_[0][2] }
sub size     { $_[0][3] }
sub abs_path { $_[0][4] }

sub as_scalarref {
   $_[0][0] //= ref $_[0][1] eq 'SCALAR'? \substr(${$_[0][1]}, $_[0][2], $_[0][3])
      : Sys::Export::map_or_load_file($_[0][1], $_[0][2], $_[0][3]);
}

sub as_string {
   ${ $_[0][0] // $_[0]->as_scalarref }
}

# Avoiding dependency on namespace::clean
delete @{Sys::Export::LazyFileData::}{qw( carp croak confess )};
1;

__END__