File Coverage

blib/lib/Sys/CpuLoad.pm

Criterion	Covered	Total	%
statement	48	52	92.3
branch	13	22	59.0
condition	3	9	33.3
subroutine	12	12	100.0
pod	3	3	100.0
total	79	98	80.6

package Sys::CpuLoad;

# ABSTRACT: retrieve system load averages

# Copyright (c) 1999-2002 Clinton Wong. All rights reserved.
# This program is free software; you can redistribute it
# and/or modify it under the same terms as Perl itself.

use v5.6;

use strict;
use warnings;

use parent qw(Exporter);

use File::Which qw(which);
use IO::File;
use IPC::Run3 qw(run3);
use XSLoader;

our @EXPORT    = qw();
our @EXPORT_OK = qw(load getloadavg proc_loadavg uptime);

our $VERSION = '0.32';

XSLoader::load 'Sys::CpuLoad', $VERSION;


our $LOAD;

sub load {
    return getloadavg(@_)   if $LOAD eq 'getloadavg';
    return proc_loadavg(@_) if $LOAD eq 'proc_loadavg';
    return uptime(@_)       if $LOAD eq 'uptime';
    die "Unknown function: $LOAD";
}


sub proc_loadavg {

    if ( -r '/proc/loadavg' ) {

        my $fh = IO::File->new( '/proc/loadavg', 'r' );
        if ( defined $fh ) {
            my $line = <$fh>;
            $fh->close();
            if ( $line =~ /^(\d+\.\d+)\s+(\d+\.\d+)\s+(\d+\.\d+)/ ) {
                return ( $1, $2, $3 );
            }
        }
    }

    return undef;
}


our $UPTIME;

sub uptime {
    local %ENV = %ENV;
    $ENV{'LC_NUMERIC'} = 'POSIX'; # ensure that decimal separator is a dot

    $UPTIME ||= which("uptime") or
        return undef;

    run3($UPTIME, \undef, \my $line);
    return undef if $? || !defined($line);
    if ( $line =~ /(\d+[,.]\d+)\s*,?\s+(\d+[,.]\d+)\s*,?\s+(\d+[,.]\d+)\s*$/m )
    {
        return ( map { my $n = $_; $n =~ tr/,/./; $n + 0 } ( $1, $2, $3 ) );
    }
    return undef;
}

sub BEGIN {

    my $this = __PACKAGE__;
    my $os   = lc $^O;

    if ( $os =~ /^(darwin|dragonfly|(free|net|open)bsd|linux|solaris|sunos)$/ ) {
        $LOAD = 'getloadavg';
    }
    elsif ( -r '/proc/loadavg' && $os ne 'cygwin' ) {
        $LOAD = 'proc_loadavg';
    }
    else {
        $LOAD = 'uptime';
    }

}


1;

__END__