File Coverage

blib/lib/Sub/Spy.pm

Criterion	Covered	Total	%
statement	40	41	97.5
branch	8	10	80.0
condition			n/a
subroutine	10	10	100.0
pod	2	2	100.0
total	60	63	95.2

package Sub::Spy;
use 5.12.0;
use strict;
use warnings;

our $VERSION = '0.04';

use parent qw/Exporter/;
our @EXPORT_OK = qw/spy inspect/;

use Hash::FieldHash qw/fieldhash/;

use Sub::Spy::Result;
use Sub::Spy::Call;


fieldhash our %f_store;

sub spy {
    my $subref = shift;

    my $store = +{};

    my $spy = sub {
        my @args = @_;
        my ($result, @array_result, $e);

        if ( wantarray ) {
            @array_result = eval { $subref->(@args); };
        }
        else {
            $result = eval { $subref->(@args); };
        }
        if ( $@ ) {
            $e = $@;
        }

        push @{$store->{calls}}, Sub::Spy::Call->new({
            args => \@args,
            exception => $e,
            return_value => wantarray ? \@array_result : $result,
        });

        return wantarray ? @array_result : $result;
    };

    $f_store{$spy} = $store;

    return $spy;
}

sub inspect {
    my $spy = shift;
    my $param = $f_store{$spy} or die "given subroutine reference is not a spy!";
    return Sub::Spy::Result->new($param);
}


1;
__END__