File Coverage

blib/lib/Sub/Rate.pm

Criterion	Covered	Total	%
statement	45	47	95.7
branch	8	10	80.0
condition			n/a
subroutine	9	9	100.0
pod	3	3	100.0
total	65	69	94.2

package Sub::Rate;
use strict;
use warnings;
use Moo;
use Carp;

our $VERSION = '0.06';

has max_rate => (
    is      => 'rw',
    default => 100,
);

has rand_func => (
    is      => 'rw',
    default => sub {
        return sub { rand($_[0]) };
    },
);

has sort => (
    is      => 'rw',
    default => 0,
);

has _func => (
    is      => 'rw',
    default => sub { [] },
);

has _default_func => (
    is => 'rw',
);

no Moo;

sub add {
    my ($self, $rate, $func) = @_;

    if ($rate eq 'default') {
        $self->_default_func($func);
    }
    else {
        my $total_rate = 0;
        $total_rate += $_->[0] for @{ $self->_func };

        if ($total_rate + $rate > $self->max_rate) {
            croak sprintf 'Exceed max_rate, current:%s max:%s',
                $total_rate + $rate, $self->max_rate;
        }

        push @{ $self->_func }, [$rate, $func];
    }
}

sub generate {
    my ($self) = @_;

    my @sorted_funcs = @{ $self->_func };
    @sorted_funcs = CORE::sort { $a->[0] <=> $b->[0] } @sorted_funcs if $self->sort;

    my $rand         = $self->rand_func;
    my $max_rate     = $self->max_rate;
    my $default_func = $self->_default_func;

    sub {
        my @args = @_;

        my $index  = $rand->($max_rate);
        my $cursor = 0;

        for my $f (@sorted_funcs) {
            $cursor += $f->[0];

            if ($index <= $cursor) {
                return $f->[1]->(@args);
            }
        }

        if ($default_func) {
            return $default_func->(@args);
        }
        else {
            return;
        }
    };
}

sub clear {
    my ($self) = @_;
    $self->_func([]);
    $self->_default_func(undef);
}

__PACKAGE__->meta->make_immutable;

__END__