File Coverage

blib/lib/Sub/Meta/Parameters.pm

Criterion	Covered	Total	%
statement	230	230	100.0
branch	116	116	100.0
condition	54	55	98.1
subroutine	40	40	100.0
pod	30	30	100.0
total	470	471	99.7

package Sub::Meta::Parameters;
use 5.010;
use strict;
use warnings;

our $VERSION = "0.15";

use Carp ();
use Scalar::Util ();

use Sub::Meta::Param;

use overload
    fallback => 1,
    eq => \&is_same_interface
    ;

sub _croak { require Carp; goto &Carp::croak }

sub param_class { return 'Sub::Meta::Param' }

sub new {
    my ($class, @args) = @_;
    my %args = @args == 1 ? %{$args[0]} : @args;

    my $self = bless \%args => $class;
    $self->set_args($args{args}) if exists $args{args};
    $self->set_invocant(delete $args{invocant}) if defined $args{invocant};
    $self->set_nshift(delete $args{nshift}) if defined $args{nshift};
    $self->set_slurpy(delete $args{slurpy}) if defined $args{slurpy};

    return $self;
}

sub nshift()    { my $self = shift; return $self->{nshift} // 0 }
sub slurpy()    { my $self = shift; return $self->{slurpy} }
sub args()      { my $self = shift; return $self->{args} // [] }
sub invocant()  { my $self = shift; return $self->{invocant} }
sub invocants() { my $self = shift; return $self->has_invocant ? [ $self->{invocant} ] : [] }
sub all_args()  { my $self = shift; return [ @{$self->invocants}, @{$self->args} ] }

sub has_args()     { my $self = shift; return defined $self->{args} }
sub has_invocant() { my $self = shift; return defined $self->{invocant} }
sub has_slurpy()   { my $self = shift; return defined $self->{slurpy} }

sub set_slurpy {
    my ($self, $v) = @_;
    $self->{slurpy} = Scalar::Util::blessed($v) && $v->isa('Sub::Meta::Param')
                    ? $v
                    : $self->param_class->new($v);
    return $self;
}

sub set_args {
    my ($self, @args) = @_;
    $self->{args} = $self->_normalize_args(@args);
    return $self;
}

sub set_nshift {
    my ($self, $v) = @_;

    unless (defined $v && ($v == 0 || $v == 1) ) {
        _croak sprintf("Can't set this nshift: %s", $v//'');
    }

    $self->{nshift} = $v;

    if ($v == 1 && !defined $self->invocant) {
        my $default_invocant = $self->param_class->new(invocant => 1);
        $self->set_invocant($default_invocant)
    }

    if ($v == 0 && defined $self->invocant) {
        delete $self->{invocant}
    }

    return $self;
}

sub set_invocant {
    my ($self, $v) = @_;

    my $invocant = Scalar::Util::blessed($v) && $v->isa('Sub::Meta::Param')
                 ? $v
                 : $self->param_class->new($v);

    $invocant->set_invocant(1);

    $self->{invocant} = $invocant;

    if ($self->nshift == 0) {
        $self->set_nshift(1);
    }

    return $self;
}

sub _normalize_args {
    my ($self, @args) = @_;
    my $args = $args[0];
    _croak 'args must be a single reference' unless @args == 1 && ref $args;

    my @normalized_args;
    if (ref $args eq 'ARRAY') {
        @normalized_args = @{$args};
    }
    elsif (ref $args eq 'HASH') {
        for my $name (sort { $a cmp $b } keys %{$args}) {
            my $v = $args->{$name};
            my $f = ref $v && ref $v eq 'HASH';
            push @normalized_args => {
                name  => $name,
                named => 1,
                ($f ? %$v : (type => $v) ),
            }
        }
    }
    else {
        @normalized_args = ($args);
    }

    return [
        map {
            Scalar::Util::blessed($_) && $_->isa('Sub::Meta::Param')
            ? $_
            : $self->param_class->new($_)
        } @normalized_args
    ]
}

sub _all_positional_required() {
    my $self = shift;
    return [ @{$self->invocants}, @{$self->positional_required} ];
}


sub positional()          { my $self = shift; return [ grep { $_->positional                 } @{$self->args} ] }
sub positional_required() { my $self = shift; return [ grep { $_->positional && $_->required } @{$self->args} ] }
sub positional_optional() { my $self = shift; return [ grep { $_->positional && $_->optional } @{$self->args} ] }

sub named()               { my $self = shift; return [ grep { $_->named                      } @{$self->args} ] }
sub named_required()      { my $self = shift; return [ grep { $_->named && $_->required      } @{$self->args} ] }
sub named_optional()      { my $self = shift; return [ grep { $_->named && $_->optional      } @{$self->args} ] }

sub args_min() {
    my $self = shift;
    my $r = 0;
    $r += @{$self->_all_positional_required};
    $r += @{$self->named_required} * 2;
    return $r
}

sub args_max() {
    my $self = shift;
    return 0 + 'Inf' if $self->slurpy || @{$self->named}; ## no critic (ProhibitMismatchedOperators)
    my $r = 0;
    $r += @{$self->_all_positional_required};
    $r += @{$self->positional_optional};
    return $r
}

sub is_same_interface {
    my ($self, $other) = @_;

    return unless Scalar::Util::blessed($other) && $other->isa('Sub::Meta::Parameters');

    if ($self->has_slurpy) {
        return unless $self->slurpy->is_same_interface($other->slurpy)
    }
    else {
        return if $other->has_slurpy;
    }

    return unless $self->nshift == $other->nshift;

    return unless @{$self->all_args} == @{$other->all_args};

    for (my $i = 0; $i < @{$self->all_args}; $i++) {
        return unless $self->all_args->[$i]->is_same_interface($other->all_args->[$i]);
    }

    return !!1;
}

sub is_relaxed_same_interface {
    my ($self, $other) = @_;

    return unless Scalar::Util::blessed($other) && $other->isa('Sub::Meta::Parameters');

    if ($self->has_slurpy) {
        return unless $self->slurpy->is_same_interface($other->slurpy)
    }

    return unless $self->nshift == $other->nshift;

    return unless @{$self->all_args} <= @{$other->all_args};

    for (my $i = 0; $i < @{$self->all_args}; $i++) {
        return unless $self->all_args->[$i]->is_relaxed_same_interface($other->all_args->[$i]);
    }

    return !!1;
}

sub is_same_interface_inlined {
    my ($self, $v) = @_;

    my @src;

    push @src => sprintf("Scalar::Util::blessed(%s) && %s->isa('Sub::Meta::Parameters')", $v, $v);

    push @src => $self->has_slurpy ? $self->slurpy->is_same_interface_inlined(sprintf('%s->slurpy', $v))
                                   : sprintf('!%s->has_slurpy', $v);

    push @src => sprintf('%d == %s->nshift', $self->nshift, $v);

    push @src => sprintf('%d == @{%s->all_args}', scalar @{$self->all_args}, $v);

    for (my $i = 0; $i < @{$self->all_args}; $i++) {
        push @src => $self->all_args->[$i]->is_same_interface_inlined(sprintf('%s->all_args->[%d]', $v, $i))
    }

    return join "\n && ", @src;
}

sub is_relaxed_same_interface_inlined {
    my ($self, $v) = @_;

    my @src;

    push @src => sprintf("Scalar::Util::blessed(%s) && %s->isa('Sub::Meta::Parameters')", $v, $v);

    push @src => $self->slurpy->is_relaxed_same_interface_inlined(sprintf('%s->slurpy', $v)) if $self->has_slurpy;

    push @src => sprintf('%d == %s->nshift', $self->nshift, $v);

    push @src => sprintf('%d <= @{%s->all_args}', scalar @{$self->all_args}, $v);

    for (my $i = 0; $i < @{$self->all_args}; $i++) {
        push @src => $self->all_args->[$i]->is_relaxed_same_interface_inlined(sprintf('%s->all_args->[%d]', $v, $i))
    }

    return join "\n && ", @src;
}


sub error_message {
    my ($self, $other) = @_;

    return sprintf('other parameters must be Sub::Meta::Parameters. got: %s', $other // 'Undef')
        unless Scalar::Util::blessed($other) && $other->isa('Sub::Meta::Parameters');

    if ($self->has_slurpy) {
        return sprintf('invalid slurpy. got: %s, expected: %s', $other->has_slurpy ? $other->slurpy->display : '', $self->slurpy->display)
            unless $self->slurpy->is_same_interface($other->slurpy)
    }
    else {
        return 'should not have slurpy' if $other->has_slurpy;
    }

    return sprintf('nshift is not equal. got: %d, expected: %d', $other->nshift, $self->nshift)
        unless $self->nshift == $other->nshift;

    return sprintf('invalid args length. got: %d, expected: %d', scalar @{$other->all_args}, scalar @{$self->all_args})
        unless @{$self->all_args} == @{$other->all_args};

    for (my $i = 0; $i < @{$self->all_args}; $i++) {
        my $s = $self->all_args->[$i];
        my $o = $other->all_args->[$i];
        return sprintf('args[%d] is invalid. got: %s, expected: %s', $i, $o->display, $s->display)
            unless $s->is_same_interface($o);
    }

    return '';
}

sub relaxed_error_message {
    my ($self, $other) = @_;

    return sprintf('other parameters must be Sub::Meta::Parameters. got: %s', $other // 'Undef')
        unless Scalar::Util::blessed($other) && $other->isa('Sub::Meta::Parameters');

    if ($self->has_slurpy) {
        return sprintf('invalid slurpy. got: %s, expected: %s', $other->has_slurpy ? $other->slurpy->display : '', $self->slurpy->display)
            unless $self->slurpy->is_same_interface($other->slurpy)
    }

    return sprintf('nshift is not equal. got: %d, expected: %d', $other->nshift, $self->nshift)
        unless $self->nshift == $other->nshift;

    return sprintf('invalid args length. got: %d, expected: %d', scalar @{$other->all_args}, scalar @{$self->all_args})
        unless @{$self->all_args} <= @{$other->all_args};

    for (my $i = 0; $i < @{$self->all_args}; $i++) {
        my $s = $self->all_args->[$i];
        my $o = $other->all_args->[$i];
        return sprintf('args[%d] is invalid. got: %s, expected: %s', $i, $o->display, $s->display)
            unless $s->is_relaxed_same_interface($o);
    }

    return '';
}
sub display {
    my $self = shift;

    my $s = '';
    if ($self->has_invocant) {
        my $d = $self->invocant->display;
        $s .= "$d: " if $d;
    }

    if ($self->has_args) {
        $s .= join ', ', map { $_->display } @{$self->args};
    }

    if ($self->has_slurpy) {
        $s .= ', ' if $s;
        $s .= $self->slurpy->display;
    }

    if(!$self->has_args && !$self->has_slurpy) {
        $s .= '*';
    }

    return $s;
}

1;
__END__