File Coverage

blib/lib/Storage/Abstract.pm

Criterion	Covered	Total	%
statement	23	24	95.8
branch	4	6	66.6
condition	1	3	33.3
subroutine	4	4	100.0
pod	1	1	100.0
total	33	38	86.8

package Storage::Abstract;
$Storage::Abstract::VERSION = '0.008';
use v5.14;
use warnings;

use Mooish::Base -standard;

has param 'driver' => (
	coerce => (InstanceOf ['Storage::Abstract::Driver'])
		->plus_coercions(HashRef, q{ Storage::Abstract->load_driver($_) }),
	handles => [
		qw(
			store
			is_stored
			retrieve
			dispose
			list

			readonly
			set_readonly
			refresh
		)
	],
);

around BUILDARGS => sub {
	my ($orig, $self, @raw_args) = @_;
	my %args;

	if (@raw_args == 1 && ref $raw_args[0] eq 'HASH') {
		%args = %{$raw_args[0]};
	}
	else {
		%args = @raw_args;
	}

	my %other_args = %args;
	%args = ();
	foreach my $base_key (qw(driver)) {
		$args{$base_key} = delete $other_args{$base_key};
	}

	if (!ref $args{driver}) {
		$args{driver} = {
			driver => $args{driver},
			%other_args,
		};
	}

	return $self->$orig(%args);
};

sub load_driver
{
	my ($class, @raw_args) = @_;
	my %args;

	if (@raw_args == 1 && ref $raw_args[0] eq 'HASH') {
		%args = %{$raw_args[0]};
	}
	else {
		%args = @raw_args;
	}

	my $driver = delete $args{driver};
	die 'driver is required in Storage::Abstract' unless defined $driver;

	my $name = ucfirst $driver;
	my $full_namespace;
	if ($name =~ /^\+/) {
		$full_namespace = substr $name, 1;
	}
	else {
		$full_namespace = "Storage::Abstract::Driver::$name";
	}

	(my $file_path = $full_namespace) =~ s{::}{/}g;
	require "$file_path.pm";
	return $full_namespace->new(%args);
}

1;

__END__