File Coverage

blib/lib/Storage/Abstract/X.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	4	6	66.6
condition			n/a
subroutine	11	11	100.0
pod	2	2	100.0
total	58	60	96.6

package Storage::Abstract::X;
$Storage::Abstract::X::VERSION = '0.008';
use v5.14;
use warnings;

use Mooish::Base -standard;

use overload
	q{""} => "as_string",
	fallback => 1;

has param 'path' => (
	isa => Maybe [Str],
);

has param 'message' => (
	isa => Str,
	writer => -hidden,
);

has field 'caller' => (
	default => sub {
		for my $call_level (1 .. 10) {
			my @data = caller $call_level;
			return \@data
				if $data[1] !~ /^\(eval/ && $data[0] !~ /^Storage::Abstract/;
		}
		return undef;
	},
);

our $path_context;

sub raise
{
	my ($self, $error) = @_;

	if (defined $error) {
		$self = $self->new(message => $error, path => $path_context);
	}

	die $self;
}

sub as_string
{
	my ($self) = @_;

	my $raised = $self->message;
	$raised =~ s/\s+\z//;

	if (my $path = $self->path) {
		$raised .= " for path '$path'";
	}

	if (my $caller = $self->caller) {
		$raised .= ' (raised at ' . $caller->[1] . ', line ' . $caller->[2] . ')';
	}

	my $class = ref $self;
	my $pkg = __PACKAGE__;
	$class =~ s/${pkg}:://;

	return "Storage::Abstract exception: [$class] $raised";
}

## SUBCLASSES

package Storage::Abstract::X::NotFound {
$Storage::Abstract::X::NotFound::VERSION = '0.008';
use parent -norequire, 'Storage::Abstract::X';
}

package Storage::Abstract::X::Readonly {
$Storage::Abstract::X::Readonly::VERSION = '0.008';
use parent -norequire, 'Storage::Abstract::X';
}

package Storage::Abstract::X::PathError {
$Storage::Abstract::X::PathError::VERSION = '0.008';
use parent -norequire, 'Storage::Abstract::X';
}

package Storage::Abstract::X::HandleError {
$Storage::Abstract::X::HandleError::VERSION = '0.008';
use parent -norequire, 'Storage::Abstract::X';
}

package Storage::Abstract::X::StorageError {
$Storage::Abstract::X::StorageError::VERSION = '0.008';
use parent -norequire, 'Storage::Abstract::X';
}

1;

__END__