File Coverage

blib/lib/Storage/Abstract/Driver/Superpath.pm

Criterion	Covered	Total	%
statement	46	46	100.0
branch	15	16	93.7
condition	3	3	100.0
subroutine	11	11	100.0
pod	5	6	83.3
total	80	82	97.5

package Storage::Abstract::Driver::Superpath;
$Storage::Abstract::Driver::Superpath::VERSION = '0.008';
use v5.14;
use warnings;

use Mooish::Base -standard;

# need this in BEGIN block because we use constants from this package
BEGIN { extends 'Storage::Abstract::Driver' }

has param 'superpath' => (
	isa => SimpleStr,
	writer => -hidden,
);

with 'Storage::Abstract::Role::Driver::Meta';

sub BUILD
{
	my ($self) = @_;

	$self->_set_superpath(
		$self->SUPER::resolve_path(
			$self->superpath,
			allow_directory => !!1,
		)
	);
}

sub source_is_array
{
	return !!0;
}

sub _adjust_path
{
	my ($self, $name) = @_;

	my $superpath = quotemeta($self->superpath . Storage::Abstract::Driver::DIRSEP_STR);
	if ($name =~ s{^$superpath}{}) {
		return $name;
	}

	return undef;
}

sub store_impl
{
	my ($self, $path, $handle) = @_;
	my $new_path = $self->_adjust_path($path);

	Storage::Abstract::X::Readonly->raise(
		"file $path cannot be stored because it's outside of path '" . $self->superpath . "'"
	) unless defined $new_path;

	return $self->source->store($new_path, $handle);
}

sub is_stored_impl
{
	my ($self, $path, %opts) = @_;
	my $adjusted_path = $self->_adjust_path($path);

	if ($opts{directory} && !defined $adjusted_path) {
		my @parts_path = $self->split_path($path);
		my @parts_superpath = $self->split_path($self->superpath);

		for my $i (0 .. $#parts_path) {
			return !!0 if $i > $#parts_superpath;
			return !!0 if $parts_path[$i] ne $parts_superpath[$i];
		}

		# path prefix matches
		return !!1;
	}

	return !!0 unless defined $adjusted_path;
	return $self->source->is_stored($adjusted_path, %opts);
}

sub retrieve_impl
{
	my ($self, $path, $properties) = @_;
	my $new_path = $self->_adjust_path($path);

	Storage::Abstract::X::NotFound->raise("file $path was not found")
		unless defined $new_path;

	return $self->source->retrieve($new_path, $properties);
}

sub dispose_impl
{
	my ($self, $path) = @_;
	my $new_path = $self->_adjust_path($path);

	Storage::Abstract::X::NotFound->raise("file $path was not found")
		unless defined $new_path;

	return $self->source->dispose($new_path);
}

sub list_impl
{
	my $self = shift;
	my $list_aref = $self->source->list(@_);
	my $superpath = $self->superpath . Storage::Abstract::Driver::DIRSEP_STR;

	@{$list_aref} = map { $superpath . $_ } @{$list_aref};
	return $list_aref;
}

1;

__END__