File Coverage

blib/lib/Storage/Abstract/Driver/Subpath.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	1	2	50.0
condition			n/a
subroutine	11	11	100.0
pod	6	7	85.7
total	48	50	96.0

package Storage::Abstract::Driver::Subpath;
$Storage::Abstract::Driver::Subpath::VERSION = '0.008';
use v5.14;
use warnings;

use Mooish::Base -standard;

# need this in BEGIN block because we use constants from this package
BEGIN { extends 'Storage::Abstract::Driver' }

has param 'subpath' => (
	isa => SimpleStr,
	writer => -hidden,
);

with 'Storage::Abstract::Role::Driver::Meta';

sub BUILD
{
	my ($self) = @_;

	$self->_set_subpath($self->SUPER::resolve_path($self->subpath));
}

sub source_is_array
{
	return !!0;
}

sub resolve_path
{
	my ($self, $name, %opts) = @_;
	$name = $self->SUPER::resolve_path($name, %opts);

	# first resolve, then join path. If the order was reversed, leaving new
	# root would be possible.
	return $self->subpath . Storage::Abstract::Driver::DIRSEP_STR . $name;
}

sub store_impl
{
	my $self = shift;
	return $self->source->store(@_);
}

sub is_stored_impl
{
	my $self = shift;
	return $self->source->is_stored(@_);
}

sub retrieve_impl
{
	my $self = shift;
	return $self->source->retrieve(@_);
}

sub dispose_impl
{
	my $self = shift;
	return $self->source->dispose(@_);
}

sub list_impl
{
	my $self = shift;
	my $list_aref = $self->source->list(@_);
	my $subpath = quotemeta($self->subpath . Storage::Abstract::Driver::DIRSEP_STR);

	my @result;
	foreach my $name (@{$list_aref}) {
		next unless $name =~ s{^$subpath}{};
		push @result, $self->SUPER::resolve_path($name);
	}

	return \@result;
}

1;

__END__