File Coverage

blib/lib/Storage/Abstract/Driver/Composite.pm

Criterion	Covered	Total	%
statement	67	68	98.5
branch	21	28	75.0
condition			n/a
subroutine	16	16	100.0
pod	5	6	83.3
total	109	118	92.3

package Storage::Abstract::Driver::Composite;
$Storage::Abstract::Driver::Composite::VERSION = '0.008';
use v5.14;
use warnings;

use Mooish::Base -standard;

use Scalar::Util qw(blessed);

extends 'Storage::Abstract::Driver';

has field '_cache' => (
	isa => HashRef,
	clearer => 1,
	lazy => sub { {} },
);

with 'Storage::Abstract::Role::Driver::Meta';

sub source_is_array
{
	return !!1;
}

sub refresh
{
	my ($self) = @_;

	$self->_clear_cache;
}

sub _run_on_sources
{
	my ($self, $name, $callback) = @_;
	my $finished = !!0;

	# run on one cached source
	my $cached_source = defined $name ? $self->_cache->{$name} : undef;
	if ($cached_source) {
		$finished = $callback->($cached_source);
	}

	# if there was no cached source or $callback did not return true, do it on
	# all sources
	if (!$finished) {
		foreach my $source (@{$self->source}) {
			if ($finished = $callback->($source)) {
				$self->_cache->{$name} = $source
					if defined $name;
				last;
			}
		}
	}

	return $finished;
}

sub store_impl
{
	my ($self, $name, $handle) = @_;

	my $stored = $self->_run_on_sources(
		$name,
		sub {
			my $source = shift;
			return !!0 if $source->readonly;

			$source->store($name, $handle);
			return !!1;
		}
	);

	Storage::Abstract::X::StorageError->raise('could not store')
		unless $stored;
}

sub is_stored_impl
{
	my ($self, $name, %opts) = @_;

	my $stored = $self->_run_on_sources(
		$name,
		sub {
			my $source = shift;

			return $source->is_stored($name, %opts);
		}
	);

	return $stored;
}

sub retrieve_impl
{
	my ($self, $name, $properties) = @_;

	my $stored = !!0;
	my $retrieved = $self->_run_on_sources(
		$name,
		sub {
			my $source = shift;

			if ($source->is_stored($name)) {
				$stored = !!1;
				return $source->retrieve($name, $properties);
			}

			return undef;
		}
	);

	Storage::Abstract::X::NotFound->raise('file was not found')
		unless $stored;

	Storage::Abstract::X::StorageError->raise('could not retrieve')
		unless defined $retrieved;

	return $retrieved;
}

sub dispose_impl
{
	my ($self, $name) = @_;

	my $stored = !!0;
	my $disposed = $self->_run_on_sources(
		$name,
		sub {
			my $source = shift;

			if ($source->is_stored($name)) {
				$stored = !!1;
				return !!0 if $source->readonly;

				$source->dispose($name);
				return !!1;
			}

			return !!0;
		}
	);

	Storage::Abstract::X::StorageError->raise('file was not found')
		unless $stored;

	Storage::Abstract::X::StorageError->raise('could not dispose')
		unless $disposed;
}

sub list_impl
{
	my ($self, @args) = @_;

	my %all_files;
	$self->_run_on_sources(
		undef,
		sub {
			my $source = shift;

			foreach my $filename (@{$source->list(@args)}) {
				$all_files{$filename} = 1;
			}

			return !!0;
		}
	);

	return [keys %all_files];
}

1;

__END__