File Coverage

blib/lib/Spreadsheet/DataToExcel.pm

Criterion	Covered	Total	%
statement	12	59	20.3
branch	0	28	0.0
condition	0	23	0.0
subroutine	4	7	57.1
pod	2	2	100.0
total	18	119	15.1

package Spreadsheet::DataToExcel;

use warnings;
use strict;

our $VERSION = '0.0104';
use Spreadsheet::WriteExcel;
use base 'Class::Data::Accessor';
__PACKAGE__->mk_classaccessors( qw/
    data
    file
    error
/ );


sub new { bless {}, shift }

sub dump {
    my ( $self, $file, $data, $opts ) = @_;

    $opts ||= {};

    %$opts = (
        width_multiplier    => 1,
        text_wrap           => 1,
        calc_column_widths  => 1,
        center_first_row    => 1,

        %$opts,
    );

    $self->error( undef );

    $file = $self->file
        unless defined $file
            and length $file;

    return $self->_set_error('Missing filename for output')
        unless defined $file
            and length $file;

    $data = $self->data
        unless defined $data
            and ref $data eq 'ARRAY';

    return $self->_set_error('Missing data for output or data is in incorrect format (needs to be an arrayref of arrayrefs)')
        unless defined $data
            and ref $data eq 'ARRAY';

    $self->file( $file );
    $self->data( $data );

    my $wb = Spreadsheet::WriteExcel->new( $file );
    my $ws = $wb->add_worksheet;

    if ( $opts->{calc_column_widths} ) {
        my $col_num = 0;
        my @sizes;
        for ( @$data ) {
            $col_num = $#$_
                if @$_ > $col_num;

            for my $idx ( 0..$#$_ ) {
                my $length;
                if ( $opts->{text_wrap} and defined $_->[$idx] ) {
                    my @lines = split /\n/, $_->[$idx];
                    my $max_line_length = 0;
                    for ( @lines ) {
                        defined
                            or next;
                        $max_line_length = length
                            if $max_line_length < length;
                    }
                    $length = $max_line_length;
                }
                else {
                    $length = defined $_->[$idx] ? length $_->[$idx] : 0;
                }

                $sizes[$idx] = $length
                    if not defined $sizes[$idx]
                        or $sizes[$idx] < $length;
            }
        }

        for ( 0..$col_num ) {
            $ws->set_column(
                $_,
                $_,
                int($sizes[$_] * $opts->{width_multiplier}) );
        }
    }

    for my $row_num ( 0..$#$data ) {
        my $row = $data->[ $row_num ];
        ref $row eq 'ARRAY'
            or next;

        if ( $opts->{text_wrap} ) {
            my $format = $wb->add_format;
            $format->set_text_wrap;

            $format->set_align('center')
                if $opts->{center_first_row}
                    and $row_num == 0;

            $ws->set_row( $row_num, undef, $format );
        }

        for my $cell_num ( 0..$#$row ) {
            my $cell_data = $row->[$cell_num];

            $ws->write( $row_num, $cell_num, $cell_data );
        }
    }
    $wb->close;

    return 1;
}

sub _set_error {
    my ( $self, $error ) = @_;
    $self->error( $error );
    return;
}

1;
__END__