File Coverage

bin/spel-wizard.pl

Criterion	Covered	Total	%
statement	52	61	85.2
branch	15	28	53.5
condition	3	9	33.3
subroutine	8	9	88.8
pod			n/a
total	78	107	72.9

#!/usr/bin/perl -w
# -*- cperl -*-
# PODNAME: spel-wizard.pl
# ABSTRACT: converts spelchunks to to plain text
#


use strict;

use Getopt::Long;
use Pod::Usage;

use Config::Tiny;

use File::Spec;
use File::ShareDir;

use SpeL::Wizard;

sub dieExit;

my $version = 0.9;
my $author  = 'Walter Daems ';

######################################
# Read command-line options/arguments
####################################

my $opt_help;
my $opt_man;
my $opt_showconfig = 0;
my $opt_verbose = 0;
my $opt_test = 0;
my $opt_debug;


my $result =
  GetOptions( "help"       => \$opt_help,
	      "man"        => \$opt_man,
	      "showconfig" => \$opt_showconfig,
	      "verbose"    => sub{++$opt_verbose},
	      "test"       => \$opt_test,
	      "debug=s"    => \$opt_debug )
  || pod2usage( -exitval => 1,
		-output  => \*STDERR );
pod2usage( -exitval => 100, -verbose => 1 ) if ($opt_help);
pod2usage( -exitval => 101, -verbose => 2 ) if ($opt_man);

my $argument = $ARGV[0] if( @ARGV == 1 );

pod2usage( -message => "Incorrect number of arguments",
	   -exitval => 1,
	   -output  => \*STDERR ) unless( $opt_showconfig
					  or
					  defined( $argument ) );

###################
# Read config file
#################
# use 1. specific location if SPELWIZARD_CONIG is set,
#     2. else, home configuration folder,
#     3. or else, distribution folder
my $home = $^O eq 'MSWin32' ? $ENV{'userprofile'} : $ENV{'HOME'};
my $configdir = $ENV{'SPELWIZARD_CONFIG'}
  // File::Spec->catfile( $home, '.spel-wizard' );
my $configfilename = ( File::Spec->catfile( $configdir, 'tts.conf' ) );
$configfilename =
  File::Spec->catfile( File::ShareDir::dist_dir( 'SpeL-Wizard' ) ,
		       "tts.conf") if ( ! -r $configfilename );
dieExit( 13, "Error: cannot find config file" )
  unless( -r $configfilename );
my $config = Config::Tiny->read( $configfilename )
  or dieExit( 14, $Config::Tiny::errstr . "\nin file '$configfilename'\n" );


########################
# generate opening line
######################
my $openingline = "spel-wizard.pl - v$version - $author";
say STDERR $openingline . "\n" .
  ("=" x length( $openingline ) )
  if( $opt_verbose >= 1 );

say STDERR "- Reading configuration file from $configfilename";

if( $opt_showconfig ) {
  say STDERR Data::Dumper->Dump( [ $config ], [ qw(Configuration) ] );
  exit(0);
}

my $spelWizard = SpeL::Wizard->new( $argument, $config );

###################
# do the hard work
#################

# parse the aux file
eval {
  $spelWizard->parseAuxFile( $opt_verbose, $opt_test )
    or exit( 102 );
  1;
} or do {
  say STDERR "$@";
  exit( 15 );
};

# parse the spelidx file / generate the audio / generate the playlist
eval {
  $spelWizard->parseChunks( $opt_verbose, $opt_test, $opt_debug );
  1;
} or do {
  say STDERR "$@";
  exit( 16 );
};

########################
# generate closing line
######################
say STDERR "Done." if( $opt_verbose >= 1 );

#########################################################

sub dieExit {
  my ( $code, $message ) = @_;
  say STDERR $message;
  exit( $code );
}

__END__