File Coverage

blib/lib/Software/Policy/CodeOfConduct.pm

Criterion	Covered	Total	%
statement	45	49	91.8
branch			n/a
condition	1	3	33.3
subroutine	13	14	92.8
pod	1	1	100.0
total	60	67	89.5

package Software::Policy::CodeOfConduct;

# ABSTRACT: generate a Code of Conduct policy

use v5.20;

use Moo;

use File::ShareDir qw( dist_file );
use Path::Tiny 0.018 qw( cwd path );
use Text::Template 1.48;
use Text::Wrap    qw( wrap $columns );
use Types::Common qw( InstanceOf Maybe NonEmptyStr NonEmptySimpleStr PositiveOrZeroInt );

use experimental qw( lexical_subs signatures );

use namespace::autoclean;

our $VERSION = 'v0.5.0';


has policy => (
    is      => 'ro',
    default => 'Contributor_Covenant_1.4',
);


has name => (
    is      => 'ro',
    isa     => Maybe [NonEmptySimpleStr],
    default => sub { return undef },
);


has contact => (
    is       => 'ro',
    required => 1,
    isa      => NonEmptySimpleStr,
);


has entity => (
    is      => 'ro',
    isa     => NonEmptySimpleStr,
    default => 'project',
);


has Entity => (
    is      => 'lazy',
    isa     => NonEmptySimpleStr,
    builder => sub($self) {
        return ucfirst( $self->entity );
    },
);


has template_path => (
    is      => 'lazy',
    isa     => InstanceOf ['Path::Tiny'],
    coerce  => \&path,
    builder => sub($self) {
        return path( dist_file( __PACKAGE__ =~ s/::/-/gr , $self->policy . ".md.tmpl" ) );
    },
);

has _template => (
    is       => 'lazy',
    isa      => InstanceOf ['Text::Template'],
    init_arg => undef,
    builder  => sub($self) {
        return Text::Template->new(
            TYPE   => "FILE",
            SOURCE => $self->template_path,
        );
    }

);


has text_columns => (
    is      => 'ro',
    isa     => PositiveOrZeroInt,
    default => 78,
);


has fulltext => (
    is      => 'lazy',
    isa     => NonEmptyStr,
    init_arg => undef,
    builder => sub($self) {
        state $c = 1;
        my $pkg = __PACKAGE__ . "::Run_" . $c++;
        my $raw = $self->_template->fill_in(
            PACKAGE => $pkg,
            STRICT  => 1,
            BROKEN  => sub(%args) { die $args{error} },
            HASH    => {
                name    => $self->name // "",
                contact => $self->contact,
                entity  => $self->entity,
                Entity  => $self->Entity,
            },
        );

        $columns = $self->text_columns;
        my sub _wrap($line) {
            return $line unless $columns;
            return $line if $line =~ /^[ ]{4}/; # ignore preformatted code
            return wrap( "", $line =~ /^[\*\-](?![\*\-]) ?/ ? "  " : "", $line =~ s/[ ][ ]+/ /gr );
        }

        my @lines = map { _wrap($_) } split /\n/, $raw;
        return join( "\n", @lines );
    }
);


*text = \&fulltext;


has filename => (
    is      => 'ro',
    isa     => NonEmptySimpleStr,
    coerce  => sub($name) { return path($name)->basename },
    default => 'CODE_OF_CONDUCT.md',
);

sub save($self, $dir = undef) {


    my $path = path( $dir // cwd, $self->filename );
    $path->spew_raw( $self->fulltext );
    return $path;
}


1;

__END__