File Coverage

lib/Sisimai/Reason/NotAccept.pm

Criterion	Covered	Total	%
statement	27	27	100.0
branch	8	8	100.0
condition	11	12	91.6
subroutine	7	7	100.0
pod	2	4	50.0
total	55	58	94.8

package Sisimai::Reason::NotAccept;
use v5.26;
use strict;
use warnings;

sub text  { 'notaccept' }
sub description { 'Delivery failed due to a destination mail server does not accept any email' }
sub match {
    # Try to match that the given text and regular expressions
    # @param    [String] argv1  String to be matched with regular expressions
    # @return   [Integer]       0: Did not match
    #                           1: Matched
    # @since v4.0.0
    my $class = shift;
    my $argv1 = shift // return 0;

    # Destination mail server does not accept any message
    state $index = [
        "destination seem to reject all mails", # OpenSMTPD/smtp/mta.c
        "does not accept mail",                 # Sendmail, iCloud
        "mail receiving disabled",
        "mx or srv record indicated no smtp ",  # Exim/routers/dnslookup.c:328
        "name server: .: host not found",       # Sendmail
        "no host found for existing smtp ",     # Exim/transports/smtp.c:3502
        "no route for current request",
        "null mx",
    ];
    state $pairs = [
        ["no mx ", "found for "], # OpenSMTPD/smtp/mta.c
    ];
    return 1 if grep { rindex($argv1, $_) > -1 } @$index;
    return 1 if grep { Sisimai::String->aligned(\$argv1, $_) } @$pairs;
    return 0;
}

sub true {
    # Remote host does not accept any message
    # @param    [Sisimai::Fact] argvs   Object to be detected the reason
    # @return   [Integer]               1: Not accept
    #                                   0: Accept
    # @since v4.0.0
    # @see http://www.ietf.org/rfc/rfc2822.txt
    my $class = shift;
    my $argvs = shift // return 0;
    my $reply = $argvs->{'replycode'} || 0;

    # SMTP Reply Code is 521, 554 or 556
    require Sisimai::SMTP::Command;
    return 1 if $argvs->{'reason'} eq 'notaccept' || $reply == 521 || $reply == 556;
    return 0 if grep { $argvs->{'command'} eq $_ } Sisimai::SMTP::Command->BeforeRCPT->@*;
    return __PACKAGE__->match(lc $argvs->{'diagnosticcode'});
}

1;
__END__