File Coverage

lib/Sisimai/Reason/SpamDetected.pm

Criterion	Covered	Total	%
statement	33	33	100.0
branch	11	12	91.6
condition	6	6	100.0
subroutine	9	9	100.0
pod	2	4	50.0
total	61	64	95.3

package Sisimai::Reason::SpamDetected;
use v5.26;
use strict;
use warnings;
use Sisimai::String;
use Sisimai::SMTP::Command;

sub text  { 'spamdetected' }
sub description { 'Email rejected by spam filter running on the remote host' }
sub match {
    # Try to match that the given text and regular expressions
    # @param    [String] argv1  String to be matched with regular expressions
    # @return   [Integer]       0: Did not match
    #                           1: Matched
    # @since v4.1.19
    my $class = shift;
    my $argv1 = shift // return 0;

    state $index = [
        "blacklisted url in message",
        "block for spam",
        "blocked by policy: no spam please",
        "blocked by spamassassin", # rejected by SpamAssassin
        "classified as spam and is rejected",
        "content filter rejection",
        "denied due to spam list",
        "identified spam", # 554 SpamBouncer identified SPAM, message permanently rejected (#5.3.0)
        "may consider spam",
        "message content rejected",
        "message has been temporarily blocked by our filter",
        "message is being rejected as it seems to be a spam",
        "message was rejected by recurrent pattern detection system",
        "our email server thinks this email is spam",
        "reject bulk.advertising",
        "spam check",
        "spam content ",
        "spam detected",
        "spam email",
        "spam-like header",
        "spam message",
        "spam not accepted",
        "spam refused",
        "spamming not allowed",
        "unsolicited ",
        "your email breaches local uribl policy",
    ];
    state $pairs = [
        ["accept", " spam"],
        ["appears", " to ", "spam"],
        ["bulk", "mail"],
        ["considered", " spam"],
        ["contain", " spam"],
        ["detected", " spam"],
        ["greylisted", " please try again in"],
        ["mail score (", " over "],
        ["mail rejete. mail rejected. ", "506"],
        ["message ", "as spam"],
        ["message ", "like spam"],
        ["message ", "spamprofiler"],
        ["probab", " spam"],
        ["refused by", " spamprofiler"],
        ["reject", " content"],
        ["reject, id=", "spam"],
        ["rejected by ", " (spam)"],
        ["rejected due to spam ", "classification"],
        ["rule imposed as ", " is blacklisted on"],
        ["score", "spam"],
        ["spam ", "block"],
        ["spam ", "filter"],
        ["spam ", " exceeded"],
        ["spam ", "score"],
    ];
    return 1 if grep { rindex($argv1, $_) > -1 } @$index;
    return 1 if grep { Sisimai::String->aligned(\$argv1, $_) } @$pairs;
    return 0;
}

sub true {
    # Rejected due to spam content in the message
    # @param    [Sisimai::Fact] argvs   Object to be detected the reason
    # @return   [Integer]               1: rejected due to spam
    #                                   0: is not rejected due to spam
    # @since v4.1.19
    # @see http://www.ietf.org/rfc/rfc2822.txt
    my $class = shift;
    my $argvs = shift // return 0; return 0 unless $argvs->{'deliverystatus'};

    return 1 if $argvs->{'reason'} eq 'spamdetected';
    return 1 if (Sisimai::SMTP::Status->name($argvs->{'deliverystatus'}) || '') eq 'spamdetected';

    # The value of "reason" isn't "spamdetected" when the value of "command" is an SMTP command to
    # be sent before the SMTP DATA command because all the MTAs read the headers and the entire
    # message body after the DATA command.
    return 0 if grep { $argvs->{'command'} eq $_ } Sisimai::SMTP::Command->ExceptDATA->@*;
    return __PACKAGE__->match(lc $argvs->{'diagnosticcode'});
}

1;
__END__