File Coverage

lib/Sisimai/Reason/HostUnknown.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	12	12	100.0
condition	8	10	80.0
subroutine	8	8	100.0
pod	2	4	50.0
total	65	69	94.2

package Sisimai::Reason::HostUnknown;
use v5.26;
use strict;
use warnings;
use Sisimai::String;

sub text  { 'hostunknown' }
sub description { "Delivery failed due to a domain part of a recipient's email address does not exist" }
sub match {
    # Try to match that the given text and regular expressions
    # @param    [String] argv1  String to be matched with regular expressions
    # @return   [Integer]       0: Did not match
    #                           1: Matched
    # @since v4.0.0
    my $class = shift;
    my $argv1 = shift // return 0;

    state $index = [
        "domain is not reachable",
        "domain mentioned in email address is unknown",
        "domain must exist",
        "host or domain name not found",
        "host unknown",
        "host unreachable",
        "name or service not known",
        "no such domain",
        "recipient address rejected: unknown domain name",
        "unknown host",
    ];
    state $pairs = [
        ["domain ", "not exist"],
        ["unrout", "able ", "address"],
    ];

    return 1 if grep { rindex($argv1, $_) > -1 } @$index;
    return 1 if grep { Sisimai::String->aligned(\$argv1, $_) } @$pairs;
    return 0;
}

sub true {
    # Whether the host is unknown or not
    # @param    [Sisimai::Fact] argvs   Object to be detected the reason
    # @return   [Integer]               1: is unknown host
    #           [Integer]               0: is not unknown host.
    # @since v4.0.0
    # @see http://www.ietf.org/rfc/rfc2822.txt
    my $class = shift;
    my $argvs = shift // return 0;

    require Sisimai::SMTP::Command;
    return 1 if $argvs->{'reason'} eq 'hostunknown';
    return 0 if grep { $argvs->{'command'} eq $_ } Sisimai::SMTP::Command->BeforeRCPT->@*;

    my $statuscode = $argvs->{'deliverystatus'}    // '';
    my $issuedcode = lc $argvs->{'diagnosticcode'} // '';

    if( (Sisimai::SMTP::Status->name($statuscode) || '') eq 'hostunknown' ) {
        # To prevent classifying DNS errors as "HostUnknown"
        require Sisimai::Reason::NetworkError;
        return 1 unless Sisimai::Reason::NetworkError->match($issuedcode);

    } else {
        # Status: 5.1.2
        # Diagnostic-Code: SMTP; 550 Host unknown
        return __PACKAGE__->match($issuedcode);
    }
    return 0;
}

1;
__END__