File Coverage

lib/Sisimai/Reason/Filtered.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch	13	14	92.8
condition	8	8	100.0
subroutine	8	8	100.0
pod	2	4	50.0
total	65	68	95.5

package Sisimai::Reason::Filtered;
use v5.26;
use strict;
use warnings;
use Sisimai::SMTP::Command;

sub text  { 'filtered' }
sub description { 'Email rejected due to a header content after SMTP DATA command' }
sub match {
    # Try to match that the given text and regular expressions
    # @param    [String] argv1  String to be matched with regular expressions
    # @return   [Integer]       0: Did not match
    #                           1: Matched
    # @since v4.0.0
    my $class = shift;
    my $argv1 = shift // return 0;

    state $index = [
        "account is protected by",
        "has restricted sms e-mail", # AT&T
        "is not accepting any mail",
        "message filtered",
        "message rejected due to user rules",
        "not found recipient account",
        "recipient id refuse to receive mail", # Willcom
        "recipient is only accepting mail from specific email addresses", # AOL Phoenix
        "refused due to recipient preferences", # Facebook
        "user refuses to receive this mail",
        "user reject",
        "you have been blocked by the recipient",
    ];
    return 1 if grep { rindex($argv1, $_) > -1 } @$index;
    return 0;
}

sub true {
    # Rejected by domain or address filter ?
    # @param    [Sisimai::Fact] argvs   Object to be detected the reason
    # @return   [Integer]               1: is filtered
    #                                   0: is not filtered
    # @since v4.0.0
    # @see http://www.ietf.org/rfc/rfc2822.txt
    my $class = shift;
    my $argvs = shift // return 0; return 1 if $argvs->{'reason'} eq 'filtered';

    my $tempreason = Sisimai::SMTP::Status->name($argvs->{'deliverystatus'}) || '';
    return 0 if $tempreason eq 'suspend';

    require Sisimai::Reason::UserUnknown;
    my $issuedcode = lc $argvs->{'diagnosticcode'};
    my $thecommand = $argvs->{'command'} || '';
    if( $tempreason eq 'filtered' ) {
        # Delivery status code points "filtered".
        return 1 if Sisimai::Reason::UserUnknown->match($issuedcode);
        return __PACKAGE__->match($issuedcode);

    } else {
        # The value of "reason" isn't "filtered" when the value of "command" is an SMTP command to
        # be sent before the SMTP DATA command because all the MTAs read the headers and the entire
        # message body after the DATA command.
        return 0 if grep { $argvs->{'command'} eq $_ } Sisimai::SMTP::Command->ExceptDATA->@*;
        return 1 if __PACKAGE__->match($issuedcode);
        return Sisimai::Reason::UserUnknown->match($issuedcode);
    }
}

1;
__END__