File Coverage

lib/Sisimai/Reason/EmailTooLarge.pm

Criterion	Covered	Total	%
statement	26	26	100.0
branch	8	8	100.0
condition	7	8	87.5
subroutine	7	7	100.0
pod	2	4	50.0
total	50	53	94.3

package Sisimai::Reason::EmailTooLarge;
use v5.26;
use strict;
use warnings;

sub text  { 'emailtoolarge' }
sub description { 'Email rejected due to an email size is too big for a destination mail server' }
sub match {
    # Try to match that the given text and regular expressions
    # @param    [String] argv1  String to be matched with regular expressions
    # @return   [Integer]       0: Did not match
    #                           1: Matched
    # @since v4.0.0
    my $class = shift;
    my $argv1 = shift // return 0;

    state $index = [
        "line limit exceeded",
        "mail file size exceeds the maximum size allowed for mail delivery",
        "message too large",
        "size limit",
        "taille limite du message atteinte",
    ];
    state $pairs = [
        ["exceeded", "message size"],
        ["message ", "exceeds ", "limit"],
        ["message ", "size", "exceed"],
        ["message ", "too", "big"],
    ];
    return 1 if grep { rindex($argv1, $_) > -1 } @$index;
    return 1 if grep { Sisimai::String->aligned(\$argv1, $_) } @$pairs;
    return 0;
}

sub true {
    # The message size is too big for the remote host
    # @param    [Sisimai::Fact] argvs   Object to be detected the reason
    # @return   [Integer]               1: is too big message size
    #                                   0: is not big
    # @since v4.0.0
    # @see http://www.ietf.org/rfc/rfc2822.txt
    my $class = shift;
    my $argvs = shift // return 0; return 1 if $argvs->{'reason'} eq 'emailtoolarge';

    my $statuscode = $argvs->{'deliverystatus'} // '';
    my $tempreason = Sisimai::SMTP::Status->name($statuscode) || '';

    # Delivery status code points "emailtoolarge".
    # Status: 5.3.4
    # Diagnostic-Code: SMTP; 552 5.3.4 Error: message file too big
    #
    # Status: 5.2.3
    # Diagnostic-Code: Message length exceeds administrative limit
    return 1 if $tempreason eq 'emailtoolarge';
    return __PACKAGE__->match(lc $argvs->{'diagnosticcode'});
}

1;
__END__