File Coverage

lib/Sisimai/Mail/Maildir.pm

Criterion	Covered	Total	%
statement	55	55	100.0
branch	15	22	68.1
condition	5	5	100.0
subroutine	8	8	100.0
pod	2	2	100.0
total	85	92	92.3

package Sisimai::Mail::Maildir;
use v5.26;
use strict;
use warnings;
use IO::Dir;
use IO::File;
use Class::Accessor::Lite (
    'new' => 0,
    'ro'  => [
        'dir',      # [String] Path to Maildir/
    ],
    'rw'  => [
        'path',     # [String] Path to each file
        'file',     # [String] Each file name of a mail in the Maildir/
        'size',     # [Integer] The number of email files in the Maildir/
        'offset',   # [Integer] The number of email files which have been read
        'handle',   # [IO::Dir] Directory handle
    ]
);

sub new {
    # Constructor of Sisimai::Mail::Maildir
    # @param    [String] argv1              Path to Maildir/
    # @return   [Sisimai::Mail::Maildir]    Object
    #           [Undef]                     is not a directory or does not exist
    my $class = shift;
    my $argv1 = shift // return undef; return undef unless -d $argv1;
    my $files = 0;

    eval {
        # Count the number of files in the Maildir/
        opendir MAILDIR, $argv1;
        while( my $e = readdir MAILDIR ) {
            next unless -f sprintf("%s/%s", $argv1, $e);
            $files += 1;
        }
        closedir MAILDIR;
    };

    my $param = {
        'dir'    => $argv1,
        'file'   => undef,
        'path'   => undef,
        'size'   => $files,
        'offset' => 0,
        'handle' => IO::Dir->new($argv1),
    };
    return bless($param, __PACKAGE__);
}

sub read {
    # Maildir reader, works as an iterator.
    # @return       [String] Contents of file in Maildir/
    my $self = shift;
    return "" unless defined $self->{'dir'};
    return "" unless -d $self->{'dir'};
    return "" unless $self->{'offset'} < $self->{'size'};

    my $seekhandle = $self->{'handle'};
    my $readbuffer = '';

    eval {
        $seekhandle = IO::Dir->new($self->{'dir'}) unless $seekhandle;
        while( my $r = $seekhandle->read ) {
            # Read each file in the directory
            next if( $r eq '.' || $r eq '..' );

            my $emailindir =  $self->{'dir'}.'/'.$r;
               $emailindir =~ y{/}{}s;
            $self->{'offset'} += 1;
            next unless -f $emailindir;
            next unless -s $emailindir;
            next unless -r $emailindir;

            $self->{'path'} = $emailindir;
            $self->{'file'} = $r;
            my $filehandle = IO::File->new($emailindir, 'r');
               $readbuffer = do { local $/; <$filehandle> };
               $filehandle->close;
            last;
        }
        $seekhandle->close unless $self->{'offset'} < $self->{'size'};
    };
    return $readbuffer;
}

1;
__END__