File Coverage

lib/Sisimai/Lhost/X6.pm

Criterion	Covered	Total	%
statement	51	54	94.4
branch	18	22	81.8
condition	9	10	90.0
subroutine	6	6	100.0
pod	2	2	100.0
total	86	94	91.4

package Sisimai::Lhost::X6;
use parent 'Sisimai::Lhost';
use v5.26;
use strict;
use warnings;

sub description { 'Unknown MTA #6' }
sub inquire {
    # Detect an error from Unknown MTA #6
    # @param    [Hash] mhead    Message headers of a bounce email
    # @param    [String] mbody  Message body of a bounce email
    # @return   [Hash]          Bounce data list and message/rfc822 part
    # @return   [undef]         failed to decode or the arguments are missing
    # @since v4.25.6
    my $class = shift;
    my $mhead = shift // return undef;
    my $mbody = shift // return undef;

    return undef unless $mhead->{'subject'};
    return undef if index($mhead->{'subject'}, 'There was an error sending your mail') != 0;

    state $indicators = __PACKAGE__->INDICATORS;
    state $boundaries = ['The attachment contains the original mail headers'];
    state $startingof = {'message' => ['We had trouble delivering your message. Full details follow:']};

    my $dscontents = [__PACKAGE__->DELIVERYSTATUS]; my $v = undef;
    my $emailparts = Sisimai::RFC5322->part($mbody, $boundaries);
    my $readcursor = 0;     # (Integer) Points the current cursor position
    my $recipients = 0;     # (Integer) The number of 'Final-Recipient' header

    for my $e ( split("\n", $emailparts->[0]) ) {
        # Read error messages and delivery status lines from the head of the email to the previous
        # line of the beginning of the original message.
        unless( $readcursor ) {
            # Beginning of the bounce message or message/delivery-status part
            $readcursor |= $indicators->{'deliverystatus'} if index($e, $startingof->{'message'}->[0]) == 0;
            next;
        }
        next if ($readcursor & $indicators->{'deliverystatus'}) == 0 || $e eq "";

        # We had trouble delivering your message. Full details follow:
        #
        # Subject: 'Nyaan'
        # Date: 'Thu, 29 Apr 2012 23:34:45 +0000'
        #
        # 1 error(s):
        #
        # SMTP Server  rejected recipient
        #   (Error following RCPT command). It responded as follows: [550 5.1.1 User unknown]
        $v = $dscontents->[-1];
        my $p1 = index($e, 'The following recipients returned permanent errors: ');
        my $p2 = index($e, 'SMTP Server <');
        if( $p1 == 0 || $p2 == 0 ) {
            # SMTP Server  rejected recipient
            # The following recipients returned permanent errors: [e-mail].
            if( $v->{'recipient'} ) {
                # There are multiple recipient addresses in the message body.
                push @$dscontents, __PACKAGE__->DELIVERYSTATUS;
                $v = $dscontents->[-1];
            }
            if( $p1 == 0 ) {
                # The following recipients returned permanent errors: [e-mail].
                $p1 = index($e, 'errors: ');
                $p2 = index($e, ' ', $p1 + 8);
                $v->{'recipient'} = Sisimai::Address->s3s4(substr($e, $p1 + 8, $p2 - $p1 - 8));

            } elsif( $p2 == 0 ) {
                # SMTP Server  rejected recipient
                $p1 = rindex($e, '<');
                $p2 = rindex($e, '>');
                $v->{'recipient'} = Sisimai::Address->s3s4(substr($e, $p1, $p2 - $p1));

            } else {
                next;
            }
            $v->{'diagnosis'} = $e;
            $recipients++;
        }
    }
    return undef unless $recipients;

    require Sisimai::SMTP::Command;
    for my $e ( @$dscontents ) {
        # Get the last SMTP command from the error message
        if( my $cv = Sisimai::SMTP::Command->find($e->{'diagnosis'}) ) {
            # ...(Error following RCPT command).
            $e->{'command'} = $cv;
        }
        $e->{'diagnosis'} = Sisimai::String->sweep($e->{'diagnosis'});
    }
    return {"ds" => $dscontents, "rfc822" => $emailparts->[1]};
}

1;
__END__