File Coverage

lib/Sisimai/Lhost/TrendMicro.pm

Criterion	Covered	Total	%
statement	47	53	88.6
branch	22	30	73.3
condition	19	25	76.0
subroutine	6	6	100.0
pod	2	2	100.0
total	96	116	82.7

package Sisimai::Lhost::TrendMicro;
use parent 'Sisimai::Lhost';
use v5.26;
use strict;
use warnings;

sub description { 'TREND VISION ONE(Email and Collaboration Security)' }
sub inquire {
    # Detect an error from TREND VISION ONE: Email and Collaboration Security
    # https://www.trendmicro.com/en_us/business/products/email-and-collaboration.html
    # @param    [Hash] mhead    Message headers of a bounce email
    # @param    [String] mbody  Message body of a bounce email
    # @return   [Hash]          Bounce data list and message/rfc822 part
    # @return   [undef]         failed to decode or the arguments are missing
    # @since v4.1.2
    my $class = shift;
    my $mhead = shift // return undef;
    my $mbody = shift // return undef;
    my $tryto = [
        'Mail could not be delivered',
        'メッセージを配信できません。',
        'メール配信に失敗しました',
    ];
    my $match = 0; $match ||= 1 if index($mhead->{'from'}, '"InterScan MSS"') == 0;
                   $match ||= 1 if index($mhead->{'from'}, '"InterScan Notification"') == 0;
                   $match ||= 1 if grep { $mhead->{'subject'} eq $_ } @$tryto;
    return undef unless $match;

    require Sisimai::SMTP::Command;
    state $boundaries = ['Content-type: message/rfc822'];

    my $dscontents = [__PACKAGE__->DELIVERYSTATUS]; my $v = undef;
    my $emailparts = Sisimai::RFC5322->part($mbody, $boundaries);
    my $recipients = 0;     # (Integer) The number of 'Final-Recipient' header

    for my $e ( split("\n", $emailparts->[0]) ) {
        # Read error messages and delivery status lines from the head of the email to the previous
        # line of the beginning of the original message.
        next unless length $e;

        $v = $dscontents->[-1];
        my $p1 = index($e, ' <<< ');    # Sent <<< ...
        my $p2 = index($e, ' >>> ');    # Received >>> ...
        if( index($e, '@') > 1 && index($e, ' <') > 1 && ($p1 > 1 || $p2 > 1 || index($e, 'Unable to deliver ') > -1) ) {
            # Sent <<< RCPT TO:
            # Received >>> 550 5.1.1 ... user unknown
            # Received >>> 550 5.1.1 unknown user.
            # Unable to deliver message to
            # Unable to deliver message to  (and other recipients in the same domain).
            my $cr = substr($e, rindex($e, '<') + 1, rindex($e, '>') - rindex($e, '<') - 1);
            if( $v->{'recipient'} && $cr ne $v->{'recipient'} ) {
                # There are multiple recipient addresses in the message body.
                push @$dscontents, __PACKAGE__->DELIVERYSTATUS;
                $v = $dscontents->[-1];
            }
            $v->{'recipient'} = $cr;
            $v->{'diagnosis'} = $e if index($e, 'Unable to deliver ') > -1;
            $recipients = scalar @$dscontents;
        }

        if( index($e, 'Sent <<< ') == 0 ) {
            # Sent <<< RCPT TO:
            $v->{'command'} = Sisimai::SMTP::Command->find($e);

        } elsif( index($e, 'Received >>> ') == 0 ) {
            # Received >>> 550 5.1.1 ... user unknown
            $v->{'diagnosis'} = substr($e, index($e, ' >>> ') + 4, );

        } elsif( $p1 > 0 || $p2 > 0 ) {
            # Error message in non-English
            $v->{'command'} = Sisimai::SMTP::Command->find($e) if index($e, ' >>> ') > -1;
            my $p3 = index($e, ' <<< '); next if $p3 == -1;
            $v->{'diagnosis'} = substr($e, $p3 + 4,);
        }
    }
    return undef unless $recipients;

    for my $e ( @$dscontents ) {
        # Set default values if each value is empty.
        $e->{'diagnosis'} = Sisimai::String->sweep($e->{'diagnosis'});
        $e->{'reason'} = 'userunknown' if index($e->{'diagnosis'}, 'Unable to deliver') > -1;
    }
    return {"ds" => $dscontents, "rfc822" => $emailparts->[1]};
}

1;
__END__