File Coverage

lib/Sisimai/Lhost/GoogleGroups.pm

Criterion	Covered	Total	%
statement	41	43	95.3
branch	10	18	55.5
condition	6	8	75.0
subroutine	6	6	100.0
pod	2	2	100.0
total	65	77	84.4

package Sisimai::Lhost::GoogleGroups;
use parent 'Sisimai::Lhost';
use v5.26;
use strict;
use warnings;

sub description { 'Google Groups: https://groups.google.com' }
sub inquire {
    # Detect an error from Google Groups
    # @param    [Hash] mhead    Message headers of a bounce email
    # @param    [String] mbody  Message body of a bounce email
    # @return   [Hash]          Bounce data list and message/rfc822 part
    # @return   [undef]         failed to decode or the arguments are missing
    # @since v4.25.6
    my $class = shift;
    my $mhead = shift // return undef;
    my $mbody = shift // return undef;

    return undef unless  index($$mbody, "Google Groups") > -1;
    return undef unless rindex($mhead->{'from'}, '')  > -1;
    return undef unless  index($mhead->{'subject'}, 'Delivery Status Notification') > -1;
    return undef unless exists $mhead->{'x-failed-recipients'};
    return undef unless exists $mhead->{'x-google-smtp-source'};

    # Hello [e-mail],
    #
    # We're writing to let you know that the group you tried to contact (group-name)
    # may not exist, or you may not have permission to post messages to the group.
    # A few more details on why you weren't able to post:
    #
    #  * You might have spelled or formatted the group name incorrectly.
    #  * The owner of the group may have removed this group.
    #  * You may need to join the group before receiving permission to post.
    #  * This group may not be open to posting.
    #
    # If you have questions related to this or any other Google Group,
    # visit the Help Center at https://groups.google.com/support/.
    #
    # Thanks,
    #
    # Google Groups
    state $boundaries = ['----- Original message -----', 'Content-Type: message/rfc822'];
    my $dscontents = [__PACKAGE__->DELIVERYSTATUS]; my $v = $dscontents->[-1];
    my $emailparts = Sisimai::RFC5322->part($mbody, $boundaries);
    my $recipients = 0;
    my @entiremesg = split(/\n\n/, $emailparts->[0], 5); pop @entiremesg;
    my $issuedcode = join(' ', @entiremesg); $issuedcode =~ y/\n/ /;
    my $receivedby = $mhead->{'received'} || [];
    my $recordwide = {
        'rhost'     => Sisimai::RFC5322->received($receivedby->[0])->[1],
        'reason'    => 'onhold',
        'diagnosis' => Sisimai::String->sweep($issuedcode),
    };

    # * You might have spelled or formatted the group name incorrectly.
    # * The owner of the group may have removed this group.
    # * You may need to join the group before receiving permission to post.
    # * This group may not be open to posting.
    my $fewdetails = [$emailparts->[0] =~ /^[ ]?[*][ ]?/gm] || [];
    $recordwide->{'reason'} = 'rejected' if scalar @$fewdetails == 4;

    for my $e ( split(',', $mhead->{'x-failed-recipients'}) ) {
        # X-Failed-Recipients: [e-mail], [e-mail], ...
        next unless Sisimai::Address->is_emailaddress($e);

        if( $v->{'recipient'} ) {
            # There are multiple recipient addresses in the message body.
            push @$dscontents, __PACKAGE__->DELIVERYSTATUS;
            $v = $dscontents->[-1];
        }
        $v->{'recipient'} = Sisimai::Address->s3s4($e);
        $recipients++;
        $v->{ $_ } = $recordwide->{ $_ } for keys %$recordwide;
    }
    return undef unless $recipients;
    return {"ds" => $dscontents, "rfc822" => $emailparts->[1]};
}

1;
__END__