File Coverage

lib/Sisimai/Reason/Filtered.pm

Criterion	Covered	Total	%
statement	32	32	100.0
branch	15	18	83.3
condition	6	8	75.0
subroutine	7	7	100.0
pod	2	4	50.0
total	62	69	89.8

package Sisimai::Reason::Filtered;
use feature ':5.10';
use strict;
use warnings;

sub text  { 'filtered' }
sub description { 'Email rejected due to a header content after SMTP DATA command' }
sub match {
    # Try to match that the given text and regular expressions
    # @param    [String] argv1  String to be matched with regular expressions
    # @return   [Integer]       0: Did not match
    #                           1: Matched
    # @since v4.0.0
    my $class = shift;
    my $argv1 = shift // return undef;

    state $index = [
        'because the recipient is only accepting mail from specific email addresses',   # AOL Phoenix
        'bounced address',  # SendGrid|a message to an address has previously been Bounced.
        'due to extended inactivity new mail is not currently being accepted for this mailbox',
        'has restricted sms e-mail',    # AT&T
        'is not accepting any mail',
        'message rejected due to user rules',
        'refused due to recipient preferences', # Facebook
        'resolver.rst.notauthorized',   # Microsoft Exchange
        'this account is protected by',
        'user not found',   # Filter on MAIL.RU
        'user reject',
        'we failed to deliver mail because the following address recipient id refuse to receive mail',  # Willcom
        'you have been blocked by the recipient',
    ];
    return 1 if grep { rindex($argv1, $_) > -1 } @$index;
    return 0;
}

sub true {
    # Rejected by domain or address filter ?
    # @param    [Sisimai::Data] argvs   Object to be detected the reason
    # @return   [Integer]               1: is filtered
    #                                   0: is not filtered
    # @since v4.0.0
    # @see http://www.ietf.org/rfc/rfc2822.txt
    my $class = shift;
    my $argvs = shift // return undef;
    return 1 if $argvs->reason eq 'filtered';

    my $tempreason = Sisimai::SMTP::Status->name($argvs->deliverystatus) || '';
    return 0 if $tempreason eq 'suspend';

    require Sisimai::Reason::UserUnknown;
    my $alterclass = 'Sisimai::Reason::UserUnknown';
    my $diagnostic = lc $argvs->diagnosticcode // '';

    if( $tempreason eq 'filtered' ) {
        # Delivery status code points "filtered".
        return 1 if $alterclass->match($diagnostic);
        return 1 if __PACKAGE__->match($diagnostic);

    } else {
        # The value of "reason" isn't "filtered" when the value of "smtpcommand" is an SMTP command
        # to be sent before the SMTP DATA command because all the MTAs read the headers and the
        # entire message body after the DATA command.
        return 0 if $argvs->{'smtpcommand'} =~ /\A(?:CONN|EHLO|HELO|MAIL|RCPT)\z/;
        return 1 if __PACKAGE__->match($diagnostic);
        return 1 if $alterclass->match($diagnostic);
    }
    return 0;
}


1;
__END__