File Coverage

blib/lib/Sieve/Generator/Element/IfElse.pm

Criterion	Covered	Total	%
statement	36	36	100.0
branch	8	10	80.0
condition	2	2	100.0
subroutine	6	6	100.0
pod	0	2	0.0
total	52	56	92.8

use v5.36.0;
package Sieve::Generator::Element::IfElse 0.003;
# ABSTRACT: a Sieve if/elsif/else conditional construct

use Moo;
with 'Sieve::Generator::Element';

#pod =head1 DESCRIPTION
#pod
#pod An C object renders a Sieve C/C/C construct.  It
#pod consists of a required condition and true-branch, optional additional
#pod condition/branch pairs for C clauses, and an optional final C
#pod branch.
#pod
#pod =attr cond
#pod
#pod This attribute holds the condition for the C clause.  It may be a plain
#pod string or an object doing L.
#pod
#pod =attr true
#pod
#pod This attribute holds the block or command to execute when the C condition
#pod is true.  It should be an object doing L.
#pod
#pod =attr elsifs
#pod
#pod This attribute holds an arrayref of alternating condition/block pairs for
#pod C clauses.  Each pair follows the same rules as C and C.
#pod If not provided, no C clauses are rendered.
#pod
#pod =attr else
#pod
#pod This attribute holds the block or command for the plain C clause.  If
#pod not provided, no C clause is rendered.
#pod
#pod =cut

has cond    => (is => 'ro', required => 1);
has true    => (is => 'ro', required => 1, init_arg => 'true');
has elsifs  => (is => 'ro');
has else    => (is => 'ro');

sub children ($self) {
  my @children = ($self->cond, $self->true);
  push @children, $self->elsifs->@* if $self->elsifs;
  push @children, $self->else if $self->else;
  return @children;
}

sub as_sieve ($self, $i = undef) {
  $i //= 0;
  my $indent = q{  } x $i;

  my $str = q{};

  my $in_else;

  use experimental qw(for_list);
  for my ($cond, $block) ($self->cond, $self->true, ($self->elsifs ? $self->elsifs->@* : ())) {
    my $cond_str = $cond->as_sieve($i);
    $cond_str =~ s/\A\Q$indent\E//;

    if ($in_else) {
      $str .= " elsif $cond_str " . $block->as_sieve($i);
    } else {
      $str .= $indent . "if $cond_str " . $block->as_sieve($i);
    }
    $in_else = 1;
  }

  if ($self->else) {
    $str .= " else " . $self->else->as_sieve($i);
  }

  return $str;
}

no Moo;
1;

__END__