File Coverage

blib/lib/Sieve/Generator/Lines/PrettyCommand.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	9	10	90.0
condition	1	2	50.0
subroutine	7	7	100.0
pod	2	3	66.6
total	54	57	94.7

use v5.36.0;
package Sieve::Generator::Lines::PrettyCommand 0.001;
# ABSTRACT: a Sieve command statement with arguments aligned across multiple lines

use Moo;
with 'Sieve::Generator::Lines';

use Params::Util qw(_ARRAY0);

#pod =head1 DESCRIPTION
#pod
#pod A C is like a L, but renders
#pod its arguments in groups, with each group on its own line and arguments within
#pod a group aligned to the column after the command identifier.  This is useful
#pod for commands with many tagged arguments, such as C.
#pod
#pod =attr identifier
#pod
#pod This attribute holds the name of the Sieve command.
#pod
#pod =cut

has identifier  => (is => 'ro', required => 1);

#pod =attr arg_groups
#pod
#pod This attribute holds the list of argument groups.  Each group is either an
#pod arrayref of arguments (rendered together on one line) or a single argument.
#pod Groups are rendered on successive lines, aligned after the command name.
#pod
#pod =cut

has _arg_groups => (is => 'ro', required => 1, init_arg => 'arg_groups');
sub arg_groups { $_[0]->_arg_groups->@* }

#pod =method args
#pod
#pod   my @args = $cmd->args;
#pod
#pod This method returns the flat list of all arguments, with arrayref groups
#pod expanded in place.
#pod
#pod =cut

sub args ($self) {
  return map {; _ARRAY0($_) ? @$_ : $_ } $self->arg_groups;
}

sub as_sieve ($self, $i = undef) {
  my $indent  = q{  } x ($i // 0);
  my $indent2 = q{ } x (1 + length $self->identifier);

  my $str = $indent . $self->identifier;
  my $n = 0;

  my @queue = $self->arg_groups;
  while (@queue) {
    my @next = shift @queue;
    @next = $next[0]->@* if _ARRAY0($next[0]);

    my $hunk = join q{ }, map {; ref ? $_->as_sieve(0) : $_ } @next;
    $hunk .= ";" unless @queue;
    $hunk .= "\n";

    $str .= $n++ ? "$indent$indent2$hunk" : " $hunk";
  }

  return $str;
}

no Moo;
1;

__END__