File Coverage

blib/lib/ShipIt/Step/Jaiku.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package ShipIt::Step::Jaiku;

use strict;
use warnings;
use Net::Jaiku;
use YAML 'LoadFile';


our $VERSION = '0.01';


use base qw(ShipIt::Step);


sub init {
    my ($self, $conf) = @_;
    my $config_file = $conf->value('jaiku.config');
    defined $config_file || die "jaiku.config not defined in config\n";

    $config_file =~ s/~/$ENV{HOME}/;

    -e $config_file || die "jaiku.config: $config_file does not exist\n";
    -r $config_file || die "jaiku.config: $config_file is not readable\n";

    $self->{config} = LoadFile($config_file);

    defined $self->{config}{username} or
        die "$config_file: no username defined\n";
    defined $self->{config}{userkey} or
        die "$config_file: no userkey defined\n";

    for my $key (qw(distname message)) {
        my $value = $conf->value("jaiku.$key");
        defined $value || die "jaiku.$key not defined in config\n";
        $self->{$key} = $value;
    }
}


sub run {
    my ($self, $state) = @_;

    my %vars = (
        d => $self->{distname},
        u => "http://search.cpan.org/dist/$self->{distname}",
        v => $state->version,
        '%' => '%'
    );

    (my $message = $self->{message}) =~ s/%(.)/ $vars{$1} || '%'.$1 /ge;

    # warn(), don't die(), if we couldn't send the message, because this
    # step will presumably come after uploading to CPAN, so we don't want
    # to skip the rest of the shipit process just because of that.

    if ($state->dry_run) {
        warn "*** DRY RUN, not jaikuing!\n";
        warn "message: $message\n";
        return;
    }

    my $jaiku = Net::Jaiku->new(
        username => $self->{config}{username},
        userkey  => $self->{config}{userkey},
    );

    $jaiku->setPresence(message => $message) or
        warn "couldn't send message to jaiku\n";
}


1;


__END__