File Coverage

blib/lib/ShardedKV/Continuum/Jump.pm

Criterion	Covered	Total	%
statement	13	15	86.6
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	18	20	90.0

package ShardedKV::Continuum::Jump;

# This implementation is based heavily on the ShardedKV::Continuum::CHash module by Steffen Mueller

use 5.014002;
use strict;
use warnings;

our $VERSION = '0.01';

use Algorithm::ConsistentHash::JumpHash;

use Moose;
use JSON::XS qw(encode_json decode_json);

with 'ShardedKV::Continuum';

has '_orig_continuum_spec' => (
  is => 'ro',
);

sub choose {
    my ($self, $key) = @_;
    my $idx = Algorithm::ConsistentHash::JumpHash::jumphash_siphash($key, scalar @{$self->_orig_continuum_spec->{ids}});
    return $self->_orig_continuum_spec->{ids}->[$idx];
}

sub serialize {
  my $self = shift;
  encode_json( $self->_orig_continuum_spec )
}

sub deserialize {
  my $class = shift;
  return $class->new(from => decode_json( $_[1] ));
}

sub clone {
  my $self = shift;
  my $clone = ref($self)->new(from => $self->_orig_continuum_spec);
  return $clone;
}

sub extend {
  my $self = shift;
  my $spec = shift;

  $self->_assert_spec_ok($spec);

  # Build clone of the original spec (to avoid action at a
  # distance) and add the new nodes.
  my $orig_spec = $self->_orig_continuum_spec;
  my $clone_spec = {
    %$orig_spec, # replicas + in case there's other gunk in it, at least make an effort
    ids => [ @{$orig_spec->{ids}} ], # deep clone
  };
  push @{ $clone_spec->{ids} }, @{ $spec->{ids} };

  $self->{_orig_continuum_spec} = $clone_spec;
  return 1;
}

sub get_bucket_names {
  my $self = shift;

  return @{ $self->_orig_continuum_spec()->{ids} };
}

sub BUILD {
  my ($self, $args) = @_;

  my $from = delete $args->{from};
  if (ref($from) eq 'HASH') {
    $self->{_orig_continuum_spec} = $from;
  } else {
    die "Invalid 'from' specification for " . __PACKAGE__;
  }
}

sub _assert_spec_ok {
  my ($self, $spec) = @_;
  Carp::croak("Continuum spec must be a hash of the form {ids => [qw(node1 node2 node3)]}")
    if not ref($spec) eq 'HASH'
    or not ref($spec->{ids}) eq 'ARRAY';
  return 1;
}

no Moose;
__PACKAGE__->meta->make_immutable;

__END__