File Coverage

blib/lib/Script/Nohup.pm

Criterion	Covered	Total	%
statement	41	45	91.1
branch	0	4	0.0
condition			n/a
subroutine	12	13	92.3
pod			n/a
total	53	62	85.4

package Script::Nohup;
use Mouse;
use Mouse::Util::TypeConstraints;

use 5.008001;
use utf8;
use POSIX qw/setsid/;
use Path::Class::File;
use Time::Piece;
use IO::Handle;

sub import {
    my $pkg = shift;

    $pkg->_fork;

    my $script_nohup = $pkg->new(@_);

    $SIG{HUP} = 'IGNORE';
    print "start  : ".$script_nohup->basename."\n";
    print "create : ".$script_nohup->filename."\n";

    $script_nohup->_logger();
}

our $VERSION = "0.01";

subtype "Path::Class::File" => as Object => where { $_->isa("Path::Class::File") };
coerce "Path::Class::File"
    => from "Str",
    => via { Path::Class::File->new($_) };

has script => (
     is      => "ro",
     isa     => "Path::Class::File",
     coerce  => 1,
     default => sub { $0 },
);

has basename => (
    is       => "ro",
    isa      => "Str",
    default  => sub {
        my $self = shift;
        $self->script->basename
    },
);

has filename => (
    is      => "ro",
    isa     => "Str",
    lazy    => 1,
    default => sub {
        my $self = shift;
        $self->basename.'_'.$self->exec_date.$self->file_extention;
    },
);

has file_extention => (
    is       => "ro",
    isa      => "Str",
    default  => ".log"
);

has exec_date => (
    is      => "ro",
    default => sub { localtime->ymd }
);

has file => (
    is      => "ro",
    isa     => "Path::Class::File",
    lazy    => 1,
    coerce  => 1,
    default => sub {
        my $self = shift;
        $self->script->dir->file($self->filename);
    },
);

no Mouse;


sub _fork {
    my $pid = fork();
    die "can't fork: $!" unless defined $pid;
    exit 0 if $pid;
    setsid();
}

sub _logger {
    my $self = shift;

    STDOUT->autoflush;
    STDERR->autoflush;

    $self->_add_log;
}

sub _add_log {
    my $self = shift;
    open(STDOUT,'>>',$self->file);
    open(STDERR,'>>',$self->file);
}

1;

__END__