File Coverage

blib/lib/Schedule/Activity/NodeFilter.pm

Criterion	Covered	Total	%
statement	87	90	96.6
branch	46	50	92.0
condition	16	30	53.3
subroutine	8	8	100.0
pod	0	5	0.0
total	157	183	85.7

package Schedule::Activity::NodeFilter;

use strict;
use warnings;
use Ref::Util qw/is_plain_hashref is_ref/;

our $VERSION='0.3.0';

my %property=map {$_=>undef} qw/f attr op value boolean filters mod/;
my %matcher=(
	boolean=>\&matchBoolean,
	elapsed=>\&matchElapsed,
	value  =>\&matchValue,
	avg    =>\&matchValue,
);

sub new {
	my ($ref,%opt)=@_;
	my $class=is_ref($ref)||$ref;
	my %self=map {$_=>$opt{$_}} grep {exists($opt{$_})} keys(%property);
	if($self{attr})    { $self{f}//='value' }
	if($self{boolean}) { $self{f}='boolean'; $self{boolean}=lc($self{boolean}) }
	if(!defined($matcher{$self{f}})) { die "Invalid filter function $self{f}" }
	return bless(\%self,$class);
}

sub matches {
	my ($self,$tm,%attributes)=@_;
	return &{$matcher{$$self{f}}}($self,$tm,%attributes);
}

sub matchBoolean {
	my ($self,$tm,%attributes)=@_;
	if($$self{boolean} eq 'and') {
		my $res=1;
		foreach my $filter (@{$$self{filters}}) {
			if(is_plain_hashref($filter)) { $res&&=__PACKAGE__->new(%$filter)->matches($tm,%attributes) }
			else                          { $res&&=$filter->matches($tm,%attributes) }
			if(!$res) { return 0 }
		}
		return $res;
	}
	if($$self{boolean} eq 'or') {
		my $res=0;
		foreach my $filter (@{$$self{filters}}) {
			if(is_plain_hashref($filter)) { $res||=__PACKAGE__->new(%$filter)->matches($tm,%attributes) }
			else                          { $res||=$filter->matches($tm,%attributes) }
			if($res) { return 1 }
		}
		return $res;
	}
	if($$self{boolean} eq 'nand') {
		my $res=0;
		foreach my $filter (@{$$self{filters}}) {
			if(is_plain_hashref($filter)) { $res||=!__PACKAGE__->new(%$filter)->matches($tm,%attributes) }
			else                          { $res||=!$filter->matches($tm,%attributes) }
			if($res) { return 1 }
		}
		return $res;
	}
	return 0;
}

sub matchElapsed {
	my ($self,$tm,%attributes)=@_;
	my $v=$attributes{$$self{attr}}//{};
	$v=$$v{tmmax};
	if(defined($v)&&($tm>=$v)) {
		$v=$tm-$v;
		return __PACKAGE__
			->new(f=>'value',attr=>'timecheck',op=>$$self{op},value=>$$self{value},mod=>$$self{mod})
			->matches(undef,timecheck=>{value=>$v});
	}
	return 0;
}

sub matchValue {
	my ($self,$tm,%attributes)=@_;
	my $v=$attributes{$$self{attr}}//{};
	if   ($$self{f} eq 'value') { $v=$$v{value} }
	elsif($$self{f} eq 'avg')   { $v=$$v{avg} }
	else { die "Not yet available $$self{f}" }
	if(defined($$self{value})) {
		if(!defined($v)) { return 0 }
		if(defined($$self{mod})) {
			if($v<0) { $v+=(1+int(-$v/$$self{mod}))*$$self{mod} }
			$v=$v-int($v/$$self{mod})*$$self{mod};
		}
		if($$self{op} eq 'eq') { return $v==$$self{value} }
		if($$self{op} eq 'ne') { return $v!=$$self{value} }
		if($$self{op} eq 'lt') { return $v< $$self{value} }
		if($$self{op} eq 'le') { return $v<=$$self{value} }
		if($$self{op} eq 'gt') { return $v> $$self{value} }
		if($$self{op} eq 'ge') { return $v>=$$self{value} }
	}
	return 0;
}

1;

__END__