File Coverage

blib/lib/SVK/Log/Filter/Babelfish.pm

Criterion	Covered	Total	%
statement	9	9	100.0
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	12	12	100.0

package SVK::Log::Filter::Babelfish;

use strict;
use warnings;

use base qw( SVK::Log::Filter::Selection );
use WWW::Babelfish;

our $VERSION = '0.0.3';

sub setup {
    my ($self) = @_;

    # create a WWW::Babelfish object
    my $service = $ENV{BABELFISH_SERVICE} || 'Babelfish';
    my $fish = WWW::Babelfish->new( service => $service );
    die "Can't create a babelfish using the '$service' service.\n"
        if !$fish;
    $self->{fish} = $fish;

    # determine the source and destination languages
    my ( $src_lang, $dest_lang ) = split /\s+/, $self->{argument};
    ( $dest_lang, $src_lang ) = ( $src_lang, $dest_lang ) if !$dest_lang;
    $self->{source}
        = _lang_to_name( $fish, $src_lang ) || 'English';
    $self->{destination}
        = _lang_to_name( $fish, $dest_lang ) || 'English';

    return;
}

sub revision {
    my ($self, $args) = @_;
    my $props = $args->{props};

    my $src_name  = $self->{source};
    my $dest_name = $self->{destination};
    my $text      = $props->{'svn:log'};

    my $fish = $self->{fish};
    my $new_svn_log = $fish->translate(
        source      => $src_name,
        destination => $dest_name,
        text        => $text,
    );

    die "Unable to translate from '$src_name' to '$dest_name': $text\n"
        if !$new_svn_log;

    $props->{'svn:log'} = $new_svn_log;

    return;
}

sub _lang_to_name {
    my ($fish, $lang_tag) = @_;

    return if !$lang_tag;
    my $pairs = $fish->languagepairs();

    while ( my ( $src_name, $dests ) = each %$pairs ) {
        while ( my ( $dest_name, $pair_tag ) = each %$dests ) {
            my ( $src_tag, $dest_tag ) = split /[_|]/, $pair_tag;
            return $src_name  if $lang_tag eq $src_tag;
            return $dest_name if $lang_tag eq $dest_tag;
        }
    }


    die "Unknown language tag '$lang_tag'\n";
    return;
}

1;

__END__