File Coverage

blib/lib/SQL/OOP/Where.pm

Criterion	Covered	Total	%
statement	62	82	75.6
branch	19	34	55.8
condition	10	25	40.0
subroutine	15	19	78.9
pod	14	14	100.0
total	120	174	68.9

package SQL::OOP::Where;
use strict;
use warnings;
use Scalar::Util qw(blessed);
use SQL::OOP::ID;

### ---
### Constructor
### ---
sub new {
    my $class = shift;
    return bless {}, $class;
}

### ---
### SQL::Abstract style AND factory
### ---
sub and_hash {
    warn 'Deprecated infavor of and_abstract';
    my ($class, $hash_ref, $op) = @_;
    return _append_hash($class->and, $hash_ref, $op || '=');
}

### ---
### SQL::Abstract style OR factory
### ---
sub or_hash {
    warn 'Deprecated infavor of or_abstract';
    my ($class, $hash_ref, $op) = @_;
    return _append_hash($class->or, $hash_ref, $op || '=');
}

### ---
### SQL::Abstract style AND factory
### ---
sub and_abstract {
    my ($class, $array_ref, $op) = @_;
    return _append_hash($class->and, $array_ref, $op || '=');
}

### ---
### SQL::Abstract style OR factory
### ---
sub or_abstract {
    my ($class, $array_ref, $op) = @_;
    return _append_hash($class->or, $array_ref, $op || '=');
}

### ---
### SQL::Abstract style AND factory backend
### ---
sub _append_hash {
    my ($obj, $array_ref, $op) = @_;
    my @copied = ref $array_ref eq 'HASH' ? %{$array_ref} : @{$array_ref};
    while (my($key, $val) = splice @copied, 0, 2) {
        $obj->append(__PACKAGE__->cmp($op || '=', $key, $val));
    }
    return $obj;
}

### ---
### AND factory
### ---
sub and {
    my ($class, @array) = @_;
    return SQL::OOP::Array->new(@array)->set_sepa(' AND ');
}

### ---
### OR factory
### ---
sub or {
    my ($class, @array) = @_;
    return SQL::OOP::Array->new(@array)->set_sepa(' OR ');
}

### ---
### binary operator expression factory
### ---
sub cmp {
    my ($self, $op, $key, $val) = @_;
    if (scalar @_ != 4) {
        die 'Not enough args given';
    }
    if ($key && defined $val) {
        my $quoted = SQL::OOP::ID->new($key);
        if (ref $val) {
            return SQL::OOP::Array->new($quoted->to_string, $val)->set_sepa(" $op ");
        }
        return SQL::OOP::Base->new($quoted->to_string. qq( $op ?), [$val]);
    }
}

### ---
### binary operator expression factory with sub query in value [DEPRECATED]
### ---
sub cmp_nested {
    warn 'cmp_nested is deprecated! Use cmp instead';
    my ($self, $op, $key, $val) = @_;
    if (scalar @_ != 4) {
        die 'Not enough args given';
    }
    if ($key && defined $val) {
        my $quoted = SQL::OOP::ID->new($key);
        return SQL::OOP::Array->new($quoted->to_string, $val)->set_sepa(" $op ");
    }
}

### ---
### IS NULL factory
### ---
sub is_null {
    my ($self, $key) = @_;
    if ($key) {
        my $quoted = SQL::OOP::ID->new($key);
        return SQL::OOP::Base->new($quoted->to_string. qq( IS NULL));
    }
}

### ---
### IS NOT NULL factory
### ---
sub is_not_null {
    my ($self, $key) = @_;
    if ($key) {
        my $quoted = SQL::OOP::ID->new($key);
        return SQL::OOP::Base->new($quoted->to_string. qq( IS NOT NULL));
    }
}

### ---
### BETWEEN ? AND ? factory
### ---
sub between {
    my ($self, $key, $val1, $val2) = @_;
    if ($key) {
        if (defined $val1 and defined $val2) {
            my $quoted = SQL::OOP::ID->new($key)->to_string;
            my $str = $quoted. qq( BETWEEN ? AND ?);
            return SQL::OOP::Base->new($str, [$val1, $val2]);
        } elsif (defined $val1) {
            return $self->cmp('>=', $key, $val1);
        } else {
            return $self->cmp('<=', $key, $val2);
        }
    }
}

### ---
### IN factory
### ---
sub in {
    my ($self, $key, $val) = @_;
    if ($key) {
        my $quoted = SQL::OOP::ID->new($key)->to_string;
        if (ref $val eq 'ARRAY') {
            my $placeholder = '?, ' x scalar @$val;
            $placeholder = substr($placeholder, 0, -2);
            return SQL::OOP::Base->new("$quoted IN ($placeholder)", $val);
        } elsif (blessed($val) && $val->isa('SQL::OOP::Base')) {
            return SQL::OOP::Array->new($quoted, $val)->set_sepa(" IN ");
        }
    }
}

### ---
### NOT IN factory
### ---
sub not_in {
    my ($self, $key, $val) = @_;
    if ($key) {
        my $quoted = SQL::OOP::ID->new($key)->to_string;
        if (ref $val eq 'ARRAY') {
            my $placeholder = '?, ' x scalar @$val;
            $placeholder = substr($placeholder, 0, -2);
            return SQL::OOP::Base->new("$quoted NOT IN ($placeholder)", $val);
        } elsif (blessed($val) && $val->isa('SQL::OOP::Base')) {
            return SQL::OOP::Array->new($quoted, $val)->set_sepa(" NOT IN ");
        }
    }
}

1;

__END__