File Coverage

blib/lib/SMS/Send/AT/TMobile.pm

Criterion	Covered	Total	%
statement	21	33	63.6
branch	1	8	12.5
condition	2	2	100.0
subroutine	7	7	100.0
pod	2	2	100.0
total	33	52	63.4

use strict;
use warnings;
package SMS::Send::AT::TMobile;
$SMS::Send::AT::TMobile::VERSION = '0.002';
# ABSTRACT: SMS::Send driver for the T-Mobile Austria SMSC service

use Carp;
use HTTP::Tiny;

use base 'SMS::Send::Driver';


sub new {
    my $class = shift;
    my $self = { @_ };

    $self->{$_}
        or croak "$_ missing"
            for qw( _login _password );

    return bless $self, $class;
}

sub send_sms {
    my ($self, %args) = @_;

    defined $args{_from}
        or croak "_from missing";

    my $http = HTTP::Tiny->new( timeout => 3 );

    # default to numeric sender id
    my $oa_ton = 1;
    my $oa_npi = 1;
    # alphanumerical sender id
    if ( $args{_from} !~ /^\d+$/ ) {
        $oa_ton = 5;
        $oa_npi = 0;
    }
    # the API expects the recipient without a leading +
    ( my $to = $args{to} ) =~ s/^\+//;

    my $response = $http->post_form(
        'http://213.162.67.5/cgi-bin/sendsms.fcgi',
        [
            id          => $self->{_login},
            passwd      => $self->{_password},
            rcpt_req    => 0,
            # sender
            oa          => $args{_from},
            oa_ton      => $oa_ton,
            oa_npi      => $oa_npi,
            # recipient
            da          => $to,
            da_ton      => 1,
            da_npi      => 1,
            text        => $args{text},
        ]
    );

    # for example a timeout error
    die $response->{content}
        unless $response->{success};

    # known response messages:
    # +OK 01  message(s) successfully sent to 43676012345678:msgid=0::
    # -ERR 04 Currently unavailable ::
    # -ERR 20 Unknown error ::
    return 1
        if $response->{content} =~ /^\+OK 01/;

    $@ = {
        as_string => $response->{content},
    };

    return 0;
}

1;

__END__