File Coverage

blib/lib/Rsync/Config/Renderer.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package Rsync::Config::Renderer;

use strict;
use warnings;

our $VERSION = '0.2';

use Exception::Class (
    'Rsync::Config::Renderer::Exception::Invalid::Indent' => {
        description => 'Invalid value: need a non-negative integer!',
        alias       => 'throw_invalid_indent',
    },
    'Rsync::Config::Renderer::Exception::Invalid::IndentChar' => {
        description => 'Invalid value: need a non-empty string!',
        alias       => 'throw_invalid_indent_char',
    },
);

sub new {
    my ( $class, %opt ) = @_;
    my $self;

    $self = bless { $class->_default_options, %opt }, $class;
    return $self;
}

sub indent {
    my $self = shift;

    return $self->_default_options('indent') if !ref $self;
    if (@_) {
        $self->{indent} = $self->_valid_indent(@_);
        return $self;
    }
    return $self->{indent};
}

sub indent_char {
    my $self = shift;

    return $self->_default_options('indent_char') if !ref $self;
    if (@_) {
        $self->{indent_char} = $self->_valid_indent_char(@_);
        return $self;
    }
    return $self->{indent_char};
}

sub indent_string {
    my $self = shift;
    my %opt;
    for my $opt (qw(indent indent_char)) {
        my $valid = '_valid_' . $opt;
        $opt{$opt} =
              @_        ? $self->$valid(shift)
            : ref $self ? $self->$opt
            : $self->_default_options($opt);
    }
    return $opt{indent_char} x $opt{indent};
}

sub render {
    my $self  = shift;
    my @lines = grep { !ref $_ } @_;
    my %opt   = (
        prefix => q{},
        suffix => "\n",
        map { %{$_} } grep { ref $_ eq 'HASH' } @_,
    );
    my @indent_args = ();
    for my $opt (qw(indent indent_char)) {
        next if !exists $opt{$opt};
        push @indent_args, $opt{$opt};
    }
    for my $line (@lines) {
        $line = $self->indent_string(@indent_args)
            . $opt{prefix}
            . $line
            . $opt{suffix};
    }
    return wantarray ? @lines : join q{}, @lines;
}

sub _default_options {
    my $class    = shift;
    my %defaults = (
        indent      => 0,
        indent_char => "\t",
    );
    return @_ ? $defaults{ shift() } : %defaults;
}

sub _valid_indent {
    my ( $class, $indent ) = @_;
    if ( !defined $indent || $indent !~ /^\d+$/xm ) {
        throw_invalid_indent;
    }
    return $indent;
}

sub _valid_indent_char {
    my ( $class, $char ) = @_;
    if ( !defined $char || !length $char ) {
        throw_invalid_indent;
    }
    return $char;
}

1;

__END__