File Coverage

blib/lib/Router/Simple/Reversible.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	10	10	100.0
condition	3	4	75.0
subroutine	5	5	100.0
pod	0	1	0.0
total	48	50	96.0

package Router::Simple::Reversible;
use 5.008001;
use strict;
use warnings;
use parent 'Router::Simple';

our $VERSION = "0.02";

sub path_for {
    my ($self, $dest, $args) = @_;

    $dest ||= {};
    $args ||= {};

ROUTE:
    foreach my $route (@{ $self->routes }) {
        foreach my $key (keys %$dest) {
            if ($route->dest->{$key} ne $dest->{$key}) {
                next ROUTE;
            }
        }

        my $splat_index = 0;
        my $path = $route->pattern;
        $path =~ s!
                \{((?:\{[0-9,]+\}|[^{}]+)+)\} | # /blog/{year:\d{4}}
                :([A-Za-z0-9_]+)              | # /blog/:year
                (\*)                          | # /blog/*/*
                ([^{:*]+)                       # normal string
            !
                if ($1) {
                    my ($name) = split /:/, $1, 2;
                    defined $args->{$name} ? $args->{$name} : '';
                } elsif ($2) {
                    $args->{$2};
                } elsif ($3) {
                    $args->{splat}->[$splat_index++];
                } else {
                    $4;
                }
            !gex;

        return $path;
    }

    return undef;
}

1;
__END__