File Coverage

blib/lib/Rest/Client/Builder.pm

Criterion	Covered	Total	%
statement	49	49	100.0
branch	7	10	70.0
condition			n/a
subroutine	14	14	100.0
pod	0	7	0.0
total	70	80	87.5

package Rest::Client::Builder;

use strict;
use warnings;

our $VERSION = '0.01';
our $AUTOLOAD;

sub new {
	my ($class, $opts, $path) = @_;

	return bless({
		on_request => $opts->{on_request},
		path => defined $path ? $path : '',
		opts => { %$opts },
	}, $class);
}

sub _construct {
	my ($self, $path) = (shift, shift);

	my $id = $path;
	my $class = ref($self) . '::' . $path;

	if (defined $self->{path}) {
		$path = $self->{path} . '/' . $path;
	}

	if (@_) {
		my $tail = '/' . join('/', @_);
		$id .= $tail;
		$path .= $tail;
	}

	unless ($self->{objects}->{$id}) {
		$self->{objects}->{$id} = bless(Rest::Client::Builder->new($self->{opts}, $path), $class);
	}

	no strict 'refs';
	push @{$class . '::ISA'}, ref($self);

	return $self->{objects}->{$id};
}

sub AUTOLOAD {
	my $self = shift;

	(my $method = $AUTOLOAD) =~ s{.*::}{};
	return undef if $method eq 'DESTROY';
	no strict 'refs';
	my $ref = ref($self);

	*{$ref . '::' . $method} = sub {
		my $self = shift;
		$self->_construct($method, @_);
	};

	return $self->$method(@_);
}

sub get {
	my ($self, $args) = @_;
	return $self->{on_request}->('GET', $self->{path}, $args);
}

sub post {
	my ($self, $args) = @_;
	return $self->{on_request}->('POST', $self->{path}, $args);
}

sub put {
	my ($self, $args) = @_;
	return $self->{on_request}->('PUT', $self->{path}, $args);
}

sub delete {
	my ($self, $args) = @_;
	return $self->{on_request}->('DELETE', $self->{path}, $args);
}

sub patch {
	my ($self, $args) = @_;
	return $self->{on_request}->('PATCH', $self->{path}, $args);
}

sub head {
	my ($self, $args) = @_;
	return $self->{on_request}->('HEAD', $self->{path}, $args);
}

1;

__END__