File Coverage

blib/lib/Regexp/VerbalExpressions.pm

Criterion	Covered	Total	%
statement	84	87	96.5
branch	11	14	78.5
condition			n/a
subroutine	29	30	96.6
pod	18	24	75.0
total	142	155	91.6

package Regexp::VerbalExpressions;
use 5.008005;
use strict;
use warnings;
use parent qw/Exporter/;
use overload fallback => 1, q{""} => \&source, 'qr' => \®ex;

our $VERSION = "0.02";

our @EXPORT = qw/verex/;

sub new {
    my $class = shift;
    return bless {
        s         => '',
        modifiers => {
            i => 0,
            m => 0,
            s => 0,
            x => 0,
        },
        global_matching => 0,
    }, $class;
}

sub verex { __PACKAGE__->new() }

sub add {
    my ($self, $value) = @_;
    $self->{s} .= $value;
    return $self;
}

sub regex {
    my $self = shift;
    my $enabled = my $disabled = '';
    for my $modifier (sort keys %{$self->{modifiers}}) {
        if ($self->{modifiers}{$modifier}) {
            $enabled .= $modifier;
        } else {
            $disabled .= $modifier;
        }
    }
    return qr/(?$enabled-$disabled:$self->{s})/;
}
*compile = \®ex;

sub source {
    my $self = shift;
    return $self->{s};
}
*raw = *value = \&source;

sub find {
    my ($self, $value) = @_;
    return $self->add('(?:' . quotemeta($value) . ')');
}
*then = \&find;

sub start_of_line {
    my $self = shift;
    return $self->add('^');
}

sub end_of_line {
    my $self = shift;
    return $self->add('$');
}

sub maybe {
    my ($self, $value) = @_;
    return $self->add('(?:' . quotemeta($value) . ')?');
}

sub anything {
    my $self = shift;
    return $self->add('(?:.*)');
}

sub anything_but {
    my ($self, $value) = @_;
    return $self->add('(?:[^' . quotemeta($value) . ']*)');
}

sub something {
    my $self = shift;
    return $self->add('(?:.+)');
}

sub something_but {
    my ($self, $value) = @_;
    return $self->add('(?:[^' . quotemeta($value) . ']+)');
}

sub line_break {
    my $self = shift;
    return $self->add('(?:\n|(?:\r\n))');
}
*br = \&line_break;

sub tab {
    my $self = shift;
    return $self->add('\t');
}

sub word {
    my $self = shift;
    return $self->add('\w+');
}

sub any {
    my ($self, $value) = @_;
    return $self->add('[' . quotemeta($value) . ']');
}
*any_of = \&any;

sub range {
    my ($self, @args) = @_;
    my $value = '[';
    for (my $i = 0; $i < @args; $i += 2) {
        $value .= quotemeta($args[$i]) . '-' . quotemeta($args[$i + 1]);
    }
    $value .= ']';
    return $self->add($value);
}

sub multiple {
    my ($self, $value) = @_;
    $self->add(quotemeta($value) . '+');
}

sub or {
    my ($self, $value) = @_;
    $self->add('|');
    return defined $value ? $self->find($value) : $self;
}
*alternatively = \∨

sub replace {
    my ($self, $source, $value) = @_;
    my $re = $self->regex;
    if ($self->{global_matching}) {
        $source =~ s/$re/$value/g;
    } else {
        $source =~ s/$re/$value/;
    }
    return $source;
}

sub _build_modifier {
    my ($self, $modifier, $value) = @_;
    if (!defined $value) {
        # XXX verex->with_any_case;
        $self->{modifiers}{$modifier} = 1;
    } else {
        $self->{modifiers}{$modifier} = $value ? 1 : 0;
    }
}

sub with_any_case {
    my ($self, $value) = @_;
    $self->_build_modifier(i => $value);
    return $self;
}

sub stop_at_first {
    my ($self, $value) = @_;
    if (!defined $value) {
        $self->{global_matching} = 1;
    } else {
        $self->{global_matching} = $value ? 1 : 0;
    }
    return $self;
}

sub search_one_line {
    my ($self, $value) = @_;
    $self->_build_modifier(m => $value);
    return $self;
}

1;
__END__