File Coverage

blib/lib/Redis/Script.pm

Criterion	Covered	Total	%
statement	14	39	35.9
branch	0	12	0.0
condition	0	9	0.0
subroutine	5	11	45.4
pod	3	6	50.0
total	22	77	28.5

package Redis::Script;
use 5.008005;
use strict;
use warnings;
use Exporter 'import';
our @EXPORT_OK = ('redis_eval');

our $VERSION = "0.01";

use Digest::SHA qw(sha1_hex);

sub new {
    my ($class, %args) = @_;
    my $self = bless {
        use_evalsha => 1,
        %args,
    }, $class;

    return $self;
}

sub eval {
    my ($self, $redis, $keys, $args) = @_;
    if ($self->{use_evalsha}) {
        my $sha = $self->sha1;
        my $ret = eval { $redis->evalsha($sha, scalar(@$keys), @$keys, @$args) };
        if (my $err = $@) {
            die $err if $err !~ /\[evalsha\] NOSCRIPT No matching script/i;
        } else {
            return (wantarray && ref $ret eq 'ARRAY') ? @$ret : $ret;
        }
    }

    my $ret = $redis->eval($self->{script}, scalar(@$keys), @$keys, @$args);

    return (wantarray && ref $ret eq 'ARRAY') ? @$ret : $ret;
}

sub exists {
    my ($self, $redis) = @_;
    return $redis->script_exists($self->sha1)->[0];
}

sub load {
    my ($self, $redis) = @_;
    my $sha = $self->sha1;
    my $redis_sha = $redis->script_load($self->{script});
    if (lc $sha ne lc $redis_sha) {
        die "SHA is unmatch (expected $sha but redis returns $redis_sha)";
    }
    return $sha;
}

sub sha1 {
    my $self = shift;
    return $self->{sha} ||= sha1_hex($self->{script});
}

sub redis_eval {
    my ($redis, $script, $keys, $args) = @_;
    return __PACKAGE__->new(script => $script)->eval($redis, $keys, $args);
}

1;
__END__