File Coverage

blib/lib/Range/ScalarIter.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	17	18	94.4
condition	4	5	80.0
subroutine	8	8	100.0
pod	1	1	100.0
total	67	69	97.1

package Range::ScalarIter;

our $DATE = '2019-05-12'; # DATE
our $VERSION = '0.001'; # VERSION

use strict;
use warnings;

use Exporter qw(import);
our @EXPORT_OK = qw(range_scalariter);

sub range_scalariter($$;$) {
    my ($start, $end, $step) = @_;

    tie my $scalar, 'Range::ScalarIter::Tie', $start, $end, $step;
    \$scalar;
}

package # hide from PAUSE
    Range::ScalarIter::Tie;

use Scalar::Util qw(looks_like_number);

sub TIESCALAR {
    my $class = shift;
    my ($start, $end, $step) = @_;
    $step //= 1;

    my $self = {
        start => $start,
        end   => $end,
        step  => $step,

        _ended => 0,
        _len   => 0,
        _cur   => $start,
        _buf   => [],
    };

    if (looks_like_number($start) && looks_like_number($end)) {
        $self->{_num}   = 1;
        $self->{_ended}++ if $start > $end;
    } else {
        die "Cannot specify step != 1 for non-numeric range" if $step != 1;
        $self->{_ended}++ if $start gt $end;
    }
    bless $self, $class;
}

sub _next {
    my $self = shift;

    if ($self->{_num}) {
        $self->{_ended}++ if $self->{_cur} > $self->{end};
        return if $self->{_ended};
        my $res = $self->{_cur};
        $self->{_cur} += $self->{step};
        return $res;
    } else {
        return if $self->{_ended};
        $self->{_ended}++ if $self->{_cur} ge $self->{end};
        return $self->{_cur}++;
    }
}

sub FETCH {
    my $self = shift;
    $self->_next;
}

1;
# ABSTRACT: Generate a tied-scalar iterator for range

__END__