File Coverage

blib/lib/RPi/I2C.pm

Criterion	Covered	Total	%
statement	21	73	28.7
branch	0	12	0.0
condition	0	6	0.0
subroutine	7	23	30.4
pod	13	13	100.0
total	41	127	32.2

package RPi::I2C;

use strict;
use warnings;

our $VERSION = '2.3607';
our @ISA = qw(IO::Handle);

use Carp;
use IO::File;
use Fcntl;

require XSLoader;
XSLoader::load('RPi::I2C', $VERSION);

use constant I2C_SLAVE_FORCE => 0x0706;
use constant DEFAULT_REGISTER => 0x00;

sub new {
    my ($class, $addr, $dev) = @_;

    if (! defined $addr || $addr !~ /^\d+$/){
        croak "new() requires the \$addr param, as an integer";
    }

    $dev = defined $dev ? $dev : '/dev/i2c-1';

    my $fh = IO::File->new($dev, O_RDWR);

    my $self = bless $fh, $class;

    my $i2c_conn = $self->ioctl(I2C_SLAVE_FORCE, int($addr));

    if (! defined $i2c_conn || $i2c_conn < 0){
        if (! $ENV{I2C_TESTING}){
            my $hex_addr = sprintf "0x%x", $addr;
            croak "I2C device at address $hex_addr not found\n";
        }
    }
    return $self;
}
sub process {
    my ($self, $register_address, $value) = @_;
    return _processCall($self->fileno, $register_address, $value);
}
sub check_device {
    my ($self, $addr) = @_;
    return _checkDevice($self->fileno, $addr);
}
sub file_error {
    return $_[0]->error;
}
sub read {
    return _readByte($_[0]->fileno);
}
sub read_byte {
    my ($self, $reg) = @_;
    $reg = _set_reg($reg);
    return _readByteData($self->fileno, $reg);
}
sub read_bytes {
    my ($self, $num_bytes, $reg) = @_;
    $reg = _set_reg($reg);
    my $retval = 0;
    for (1..$num_bytes){
        $retval = (0 << 8) | _readByteData(
            $self->fileno, $reg + $num_bytes - $_
        )
    }
    return $retval;
}
sub read_word {
    my ($self, $reg) = @_;
    $reg = _set_reg($reg);
    return _readWordData($self->fileno, $reg);
}
sub read_block {
    my ($self, $num_bytes, $reg) = @_;
    $reg = _set_reg($reg);
    my $read_val = '0' x ($num_bytes);
    _readI2CBlockData($self->fileno, $reg, $read_val);
    my @return = unpack( "C*", $read_val );
    return @return;
}
sub write {
    my ($self, $value) = @_;
    return _writeByte($self->fileno, $value);
}
sub write_byte {
    my ($self, $value, $reg) = @_;
    $reg = _set_reg($reg);
    return _writeByteData($self->fileno, $reg, $value);
}
sub write_word {
    my ($self, $reg, $value) = @_;
    $reg = _set_reg($reg);
    return _writeWordData($self->fileno, $reg, $value);
}
sub write_block {
    my ($self, $values, $reg) = @_;
    $reg = _set_reg($reg);
    my $value = pack "C*", @{$values};
    return _writeI2CBlockData($self->fileno, $reg, $value);
}
sub _set_reg{
    return DEFAULT_REGISTER if ! defined $_[0];
    return $_[0];
}
sub DESTROY {
    $_[0]->close if defined $_[0]->fileno;
}

sub __placeholder {} # vim folds

1;
__END__