File Coverage

blib/lib/Quantum/Superpositions/Lazy.pm

Criterion	Covered	Total	%
statement	44	45	97.7
branch	2	4	50.0
condition	9	12	75.0
subroutine	15	15	100.0
pod	7	8	87.5
total	77	84	91.6

package Quantum::Superpositions::Lazy;

our $VERSION = '1.11';

use v5.24;
use warnings;
use Carp qw(croak);
use Quantum::Superpositions::Lazy::Superposition;
use Quantum::Superpositions::Lazy::Operation::Logical;
use Quantum::Superpositions::Lazy::Util qw(is_collapsible);
use Exporter qw(import);

our @EXPORT = qw(
	superpos
);

our @EXPORT_OK = qw(
	collapse
	any_state
	every_state
	one_state
	fetch_matches
	with_sources
);

our %EXPORT_TAGS = (
	all => [@EXPORT, @EXPORT_OK],
);

our $global_reducer_type = "any";
our $global_compare_bool = 1;
our $global_sourced_calculations = 0;

sub run_sub_as
{
	my ($sub, %env) = @_;

	local $global_reducer_type = $env{reducer_type} // $global_reducer_type;
	local $global_compare_bool = $env{compare_bool} // $global_compare_bool;
	local $global_sourced_calculations = $env{sourced_calculations} // $global_sourced_calculations;
	return $sub->();
}

sub superpos
{
	my (@positions) = @_;
	my $positions_ref;

	if (@positions == 1 && ref $positions[0] eq ref []) {
		$positions_ref = $positions[0];
	}
	else {
		$positions_ref = [@positions];
	}

	return Quantum::Superpositions::Lazy::Superposition->new(
		states => $positions_ref
	);
}

sub collapse
{
	my (@superpositions) = @_;

	return map {
		croak "Element not collapsible"
			unless is_collapsible($_);
		$_->collapse;
	} @superpositions;
}

sub any_state(&)
{
	my ($sub) = @_;

	return run_sub_as $sub, reducer_type => "any";
}

sub every_state(&)
{
	my ($sub) = @_;

	return run_sub_as $sub, reducer_type => "all";
}

sub one_state(&)
{
	my ($sub) = @_;

	return run_sub_as $sub, reducer_type => "one";
}

sub fetch_matches(&)
{
	my ($sub) = @_;

	return run_sub_as $sub, compare_bool => 0;
}

sub with_sources(&)
{
	my ($sub) = @_;

	return run_sub_as $sub, sourced_calculations => 1;
}

1;
__END__